[gentoo-commits] gentoo-x86 commit in dev-libs/gjs: metadata.xml gjs-0.7.14.ebuild ChangeLog

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/05/01 15:40:39

  Added:                metadata.xml gjs-0.7.14.ebuild ChangeLog
  Log:
  Move gjs from gnome overlay to the tree
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-libs/gjs/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>gnome</herd>
  <use>
    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
      for introspection</flag>
  </use>
</pkgmetadata>



1.1                  dev-libs/gjs/gjs-0.7.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/gjs-0.7.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/gjs-0.7.14.ebuild?rev=1.1&content-type=text/plain

Index: gjs-0.7.14.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/gjs-0.7.14.ebuild,v 1.1 2011/05/01 15:40:39 nirbheek Exp $

EAPI="3"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="2"

inherit autotools eutils gnome2 python virtualx

DESCRIPTION="Javascript bindings for GNOME"
HOMEPAGE="http://live.gnome.org/Gjs"

LICENSE="MIT MPL-1.1 LGPL-2 GPL-2"
SLOT="0"
IUSE="examples test"
KEYWORDS="~amd64 ~x86"

# Things are untested and broken with anything other than xulrunner-2.0
# FIXME: https://bugzilla.mozilla.org/show_bug.cgi?id=628723 instead of libxul
RDEPEND=">=dev-libs/glib-2.18:2
	>=dev-libs/gobject-introspection-0.10.1
	>=net-libs/xulrunner-2.0:1.9

	dev-libs/dbus-glib
	sys-libs/readline
	x11-libs/cairo"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	!dev-lang/spidermonkey"
# HACK HACK: gjs-tests picks up /usr/lib/libmozjs.so with spidermonkey installed

src_prepare() {
	# AUTHORS, ChangeLog are empty
	DOCS="NEWS README"
	# FIXME: add systemtap/dtrace support, like in glib:2
	# XXX: Do NOT enable coverage, completely useless for portage installs
	G2CONF="${G2CONF}
		--disable-systemtap
		--disable-dtrace
		--disable-coverage"

	# https://bugs.gentoo.org/353941
	epatch "${FILESDIR}/${PN}-drop-js-config.patch"

	eautoreconf

	gnome2_src_prepare
	python_convert_shebangs 2 "${S}"/scripts/make-tests
}

src_test() {
	# Tests need dbus
	Xemake check || die
}

src_install() {
	# installation sometimes fails in parallel
	gnome2_src_install -j1

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins ${S}/examples/* || die "doins examples failed!"
	fi
}



1.1                  dev-libs/gjs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-libs/gjs
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/ChangeLog,v 1.1 2011/05/01 15:40:39 nirbheek Exp $

*gjs-0.7.14 (01 May 2011)

  01 May 2011; Nirbheek Chauhan <nirbheek@g.o> +gjs-0.7.14.ebuild,
  +files/gjs-drop-js-config.patch, +metadata.xml:
  Move gjs from gnome overlay to the tree