[gentoo-commits] repo/gentoo:master commit in: media-gfx/mypaint/

[Michał Górny]

commit:     bcd4cee81065125672f1903237e086c3f0db741f
Author:     Guillaume Castagnino <casta <AT> xwing <DOT> info>
AuthorDate: Tue Jul 31 20:25:34 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul 31 21:57:29 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bcd4cee8

media-gfx/mypaint: drop broken multilib handling

The current multilib handling is only partial as it moves libs to
$(get_libdir) but does not fix the python entry point to load librbries
from the correct directory. The bug is only triggered on SYMLINK_LIB
systems.
As this package will never be installed for multiple libdirs, drop this
and stick to upstream.

Closes: https://bugs.gentoo.org/648960
Closes: https://github.com/gentoo/gentoo/pull/9337
Package-Manager: Portage-2.3.44, Repoman-2.3.10

 media-gfx/mypaint/mypaint-1.2.1-r1.ebuild | 77 +++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

diff --git a/media-gfx/mypaint/mypaint-1.2.1-r1.ebuild b/media-gfx/mypaint/mypaint-1.2.1-r1.ebuild
new file mode 100644
index 00000000000..8489c3857e4
--- /dev/null
+++ b/media-gfx/mypaint/mypaint-1.2.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime gnome2-utils scons-utils toolchain-funcs python-single-r1
+
+DESCRIPTION="fast and easy graphics application for digital painters"
+HOMEPAGE="http://mypaint.org/"
+SRC_URI="https://github.com/mypaint/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+LANGS="cs de en_CA en_GB es fr hu id it ja ko nb nn_NO pl pt_BR ro ru sl sv uk zh_CN zh_TW"
+
+RDEPEND="
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pycairo-1.4[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	>=dev-libs/json-c-0.11:=
+	media-libs/lcms:2
+	>=media-libs/libmypaint-1.3.0
+	media-libs/libpng:0=
+	gnome-base/librsvg
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	virtual/pkgconfig"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	#workaround scons bug with locales. Bug #352700
+	export LANG="en_US.UTF-8"
+	tc-export CC CXX
+	escons
+}
+
+src_install () {
+	escons prefix="${D}/usr" install
+	newicon pixmaps/${PN}_logo.png ${PN}.png
+	for x in ${LANGS}; do
+		if ! has ${x} ${LINGUAS}; then
+			rm -rf "${ED}"/usr/share/locale/${x} || die
+		fi
+	done
+
+	python_optimize "${D}"usr/share/${PN}
+	# not used and broken
+	rm -r "${ED}"/usr/{include/,lib/libmypaint.a,lib/pkgconfig/} || die
+	# already provided by system-libmypaint
+	rm "${ED}"/usr/share/locale/*/LC_MESSAGES/libmypaint* || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}