[gentoo-commits] gentoo-x86 commit in dev-ml/camlp5: camlp5-6.03.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    12/01/10 13:22:35

  Modified:             ChangeLog
  Added:                camlp5-6.03.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.62                 dev-ml/camlp5/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlp5/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlp5/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlp5/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/camlp5/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	18 Dec 2011 17:33:47 -0000	1.61
+++ ChangeLog	10 Jan 2012 13:22:35 -0000	1.62
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/camlp5
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlp5/ChangeLog,v 1.61 2011/12/18 17:33:47 armin76 Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlp5/ChangeLog,v 1.62 2012/01/10 13:22:35 aballier Exp $
+
+*camlp5-6.03 (10 Jan 2012)
+
+  10 Jan 2012; Alexis Ballier <aballier@g.o> +camlp5-6.03.ebuild:
+  version bump
 
   18 Dec 2011; Raúl Porcel <armin76@g.o> camlp5-5.14.ebuild,
   camlp5-6.02.3.ebuild, camlp5-6.02.3_p1.ebuild:



1.1                  dev-ml/camlp5/camlp5-6.03.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlp5/camlp5-6.03.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlp5/camlp5-6.03.ebuild?rev=1.1&content-type=text/plain

Index: camlp5-6.03.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlp5/camlp5-6.03.ebuild,v 1.1 2012/01/10 13:22:35 aballier Exp $

EAPI="2"

inherit multilib findlib eutils

MY_P=${P%_p*}
DESCRIPTION="A preprocessor-pretty-printer of ocaml"
HOMEPAGE="http://pauillac.inria.fr/~ddr/camlp5/"
SRC_URI="http://pauillac.inria.fr/~ddr/camlp5/distrib/src/${MY_P}.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="doc +ocamlopt"

DEPEND=">=dev-lang/ocaml-3.10[ocamlopt?]"
RDEPEND="${DEPEND}"

PATCHLEVEL=${PV#*_p}
PATCHLIST=""

if [ "${PATCHLEVEL}" != "${PV}" ] ; then
	for i in $(seq 1 ${PATCHLEVEL}) ; do
		SRC_URI="${SRC_URI}
			http://pauillac.inria.fr/~ddr/camlp5/distrib/src/patch-${PV%_p*}-${i} -> ${MY_P}-patch-${i}.patch"
		PATCHLIST="${PATCHLIST} ${MY_P}-patch-${i}.patch"
	done
fi

S=${WORKDIR}/${MY_P}

src_prepare() {
	for i in ${PATCHLIST} ; do
		epatch "${DISTDIR}/${i}"
	done
}

src_configure() {
	./configure \
		-prefix /usr \
	    -bindir /usr/bin \
		-libdir /usr/$(get_libdir)/ocaml \
		-mandir /usr/share/man || die "configure failed"
}

src_compile(){
	emake || die "emake failed"
	if use ocamlopt; then
		emake  opt || die "Compiling native code programs failed"
		emake  opt.opt || die "Compiling native code programs failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	# findlib support
	insinto "$(ocamlfind printconf destdir)/${PN}"
	doins etc/META || die "failed to install META file for findlib support"

	use doc && dohtml -r doc/*

	dodoc CHANGES DEVEL ICHANGES README UPGRADING MODE
}