[gentoo-commits] gentoo-x86 commit in www-apps/trac: ChangeLog trac-0.11.6.ebuild trac-0.11.2.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/11/29 20:11:55

  Modified:             ChangeLog
  Added:                trac-0.11.6.ebuild
  Removed:              trac-0.11.2.ebuild
  Log:
  Version bump. Fix dependencies (bug #256000).
  (Portage version: 14920-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.91                 www-apps/trac/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/trac/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/trac/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/trac/ChangeLog?r1=1.90&r2=1.91

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog	17 Oct 2009 08:26:29 -0000	1.90
+++ ChangeLog	29 Nov 2009 20:11:54 -0000	1.91
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/trac
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.90 2009/10/17 08:26:29 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.91 2009/11/29 20:11:54 arfrever Exp $
+
+*trac-0.11.6 (29 Nov 2009)
+
+  29 Nov 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -trac-0.11.2.ebuild, +trac-0.11.6.ebuild:
+  Version bump. Fix dependencies (bug #256000).
 
   17 Oct 2009; <djc@g.o> trac-0.11.5.ebuild:
   Set +sqlite to make default config work (#261281).



1.1                  www-apps/trac/trac-0.11.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/trac/trac-0.11.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/trac/trac-0.11.6.ebuild?rev=1.1&content-type=text/plain

Index: trac-0.11.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/trac-0.11.6.ebuild,v 1.1 2009/11/29 20:11:54 arfrever Exp $

EAPI="2"

inherit distutils webapp

MY_PV=${PV/_beta/b}
MY_P=Trac-${MY_PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system."
HOMEPAGE="http://trac.edgewall.com/"
LICENSE="trac"
SRC_URI="http://ftp.edgewall.com/pub/trac/${MY_P}.tar.gz"

IUSE="cgi fastcgi mysql postgres +sqlite subversion"

KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

# doing so because tools, python packages... overlap
SLOT="0"
WEBAPP_MANUAL_SLOT="yes"

RDEPEND="
	dev-python/setuptools
	>=dev-python/docutils-0.3.9
	dev-python/flup
	>=dev-python/genshi-0.5
	dev-python/pygments
	dev-python/pytz
	cgi? (
		virtual/httpd-cgi
	)
	fastcgi? (
		virtual/httpd-fastcgi
	)
	mysql? (
		>=dev-python/mysql-python-1.2.1
		>=virtual/mysql-4.1
	)
	postgres? (
		>=dev-python/psycopg-2
	)
	sqlite? (
		>=dev-db/sqlite-3.3.4
		|| (
			>=dev-lang/python-2.5[sqlite]
			>=dev-python/pysqlite-2.3.2
		)
	)
	subversion? (
		>=dev-util/subversion-1.4.2[python]
	)
	!www-apps/trac-webadmin
	"
DEPEND="${RDEPEND}"

pkg_setup() {
	webapp_pkg_setup

	if ! use mysql && ! use postgres && ! use sqlite; then
		eerror "You must select at least one database backend, by enabling"
		eerror "at least one of the 'mysql', 'postgres' or 'sqlite' USE flags."
		die "no database backend selected"
	fi

	enewgroup tracd
	enewuser tracd -1 -1 -1 tracd
}

src_install() {
	webapp_src_preinst
	distutils_src_install

	# project environments might go in here
	keepdir /var/lib/trac

	# Use this as the egg-cache for tracd
	dodir /var/lib/trac/egg-cache
	keepdir /var/lib/trac/egg-cache
	fowners tracd:tracd /var/lib/trac/egg-cache

	# documentation
	cp -r contrib "${D}"/usr/share/doc/${P}/

	# tracd init script
	newconfd "${FILESDIR}"/tracd.confd tracd
	newinitd "${FILESDIR}"/tracd.initd.2 tracd

	if use cgi; then
		cp cgi-bin/trac.cgi "${D}"/${MY_CGIBINDIR} || die
	fi
	if use fastcgi; then
		cp cgi-bin/trac.fcgi "${D}"/${MY_CGIBINDIR} || die
	fi

	for lang in en; do
		webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
		webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
	done

	webapp_src_install
}