[gentoo-commits] gentoo-x86 commit in app-misc/xmind: xmind-3.3.1.201212250029.ebuild metadata.xml ChangeLog

[Chris Reffett (creffett)]

creffett    13/03/02 03:32:55

  Added:                xmind-3.3.1.201212250029.ebuild metadata.xml
                        ChangeLog
  Log:
  New package wrt bugs 295242, 375249. Thanks to Mark Dumlao <madumlao@×××××.com>, Vitovt <vitovt@××××××××××.ua>, Heiu-mun Park <padangustasana@×××××.com>, Tarcisio Fedrizzi <tarcisio.fedrizzi@×××××.com> for work in making the ebuild.
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 42618354)

Revision  Changes    Path
1.1                  app-misc/xmind/xmind-3.3.1.201212250029.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/xmind-3.3.1.201212250029.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/xmind-3.3.1.201212250029.ebuild?rev=1.1&content-type=text/plain

Index: xmind-3.3.1.201212250029.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/xmind/xmind-3.3.1.201212250029.ebuild,v 1.1 2013/03/02 03:32:55 creffett Exp $

EAPI=5

inherit eutils multilib fdo-mime gnome2-utils

MY_PN="${PN}-portable"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A brainstorming and mind mapping software tool."
HOMEPAGE="http://www.xmind.net"
SRC_URI="http://dl2.xmind.net/xmind-downloads/${MY_P}.zip"
LICENSE="EPL-1.0 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="
	>=virtual/jre-1.5
	x11-libs/gtk+:2
"
RDEPEND="${DEPEND}"

S=${WORKDIR}

QA_PRESTRIPPED="/usr/$(get_libdir)/xmind/XMind/libcairo-swt.so"

src_configure() {
	if use amd64; then
		XDIR="XMind_Linux_64bit"
	else
		XDIR="XMind_Linux"
	fi
	mv -v "$XDIR" XMind
	mv -v XMind/.eclipseproduct XMind/configuration Commons

	# force data instance & config area to be at home/.xmind directory
	sed -i -e '/-configuration/d' XMind/XMind.ini || die
	sed -i -e '/\.\/configuration/d' XMind/XMind.ini || die
	sed -i -e '/-data/d' XMind/XMind.ini || die
	sed -i -e '/\.\.\/Commons\/data\/workspace-cathy/d' XMind/XMind.ini || die
	echo '-Dosgi.instance.area=@user.home/.xmind/workspace-cathy' >> XMind/XMind.ini || die
	echo '-Dosgi.configuration.area=@user.home/.xmind/configuration-cathy' >> XMind/XMind.ini || die
}

src_compile() {
	:;
}

src_install() {
	libdir="$(get_libdir)"
	dodir   "/usr/${libdir}/xmind"
	insinto "/usr/${libdir}/xmind"
	doins   -r Commons
	doins   -r XMind

	exeinto "/usr/${libdir}/xmind/XMind"
	doexe   XMind/XMind
	dosym   "/usr/${libdir}/xmind/XMind/XMind" /usr/bin/xmind

	# insall icons
	local res
		for res in 16 32 48; do
		insinto /usr/share/icons/hicolor/${res}x${res}/apps
		newins "${FILESDIR}/xmind.${res}.png" xmind.png
	done

	# insall MIME type
	insinto /usr/share/mime/packages
	doins   "${FILESDIR}/x-xmind.xml"

	# make desktop entry
	make_desktop_entry xmind XMind xmind Office "MimeType=application/x-xmind;"
	sed -i -e "/^Exec/s/$/ %F/" "${ED}"/usr/share/applications/*.desktop

	insinto /etc/gconf/schemas
	doins "${FILESDIR}/xmind.schemas"
	dobin "${FILESDIR}/xmind-thumbnailer"
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	elog "For audio notes support, install media-sound/lame"
}

pkg_postrm() {
	gnome2_icon_cache_update
}



1.1                  app-misc/xmind/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>creffett@g.o</email>
		<name>Chris Reffett</name>
	</maintainer>
</pkgmetadata>



1.1                  app-misc/xmind/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/xmind/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-misc/xmind
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/xmind/ChangeLog,v 1.1 2013/03/02 03:32:55 creffett Exp $

*xmind-3.3.1.201212250029 (02 Mar 2013)

  02 Mar 2013; Chris Reffett <creffett@g.o> +files/x-xmind.xml,
  +files/xmind-thumbnailer, +files/xmind.16.png, +files/xmind.32.png,
  +files/xmind.48.png, +files/xmind.schemas, +metadata.xml,
  +xmind-3.3.1.201212250029.ebuild:
  New package wrt bugs 295242, 375249. Thanks to Mark Dumlao
  <madumlao@×××××.com>, Vitovt <vitovt@××××××××××.ua>, Heiu-mun Park
  <padangustasana@×××××.com>, Tarcisio Fedrizzi <tarcisio.fedrizzi@×××××.com>
  for work in making the ebuild.