[gentoo-commits] gentoo-x86 commit in media-libs/aubio: aubio-0.3.2-r2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    11/10/01 10:22:12

  Modified:             ChangeLog
  Added:                aubio-0.3.2-r2.ebuild
  Log:
  Import Fedora patch for byte-compiling errors wrt #312915 by artin Mokrejš and Sebastian Pipping
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 media-libs/aubio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/aubio/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/aubio/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/aubio/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/aubio/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	1 Oct 2011 10:08:12 -0000	1.17
+++ ChangeLog	1 Oct 2011 10:22:12 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/aubio
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/ChangeLog,v 1.17 2011/10/01 10:08:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/ChangeLog,v 1.18 2011/10/01 10:22:12 ssuominen Exp $
+
+*aubio-0.3.2-r2 (01 Oct 2011)
+
+  01 Oct 2011; Samuli Suominen <ssuominen@g.o> +aubio-0.3.2-r2.ebuild,
+  +files/aubio-0.3.2-numarray-gnuplot.patch:
+  Import Fedora patch for byte-compiling errors wrt #312915 by artin Mokrejš
+  and Sebastian Pipping
 
   01 Oct 2011; Samuli Suominen <ssuominen@g.o> aubio-0.3.2-r1.ebuild:
   Use python.eclass and set python2 as default wrt bugs #313523 and #385129



1.1                  media-libs/aubio/aubio-0.3.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/aubio/aubio-0.3.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/aubio/aubio-0.3.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: aubio-0.3.2-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/aubio-0.3.2-r2.ebuild,v 1.1 2011/10/01 10:22:11 ssuominen Exp $

EAPI=3

PYTHON_DEPEND="2:2.6"

inherit autotools eutils python

DESCRIPTION="Library for audio labelling"
HOMEPAGE="http://aubio.piem.org"
SRC_URI="http://aubio.piem.org/pub/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa doc jack lash static-libs"

RDEPEND="sci-libs/fftw:3.0
	media-libs/libsndfile
	media-libs/libsamplerate
	|| ( dev-lang/python:2.7 dev-lang/python:2.6 )
	alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )
	lash? ( media-sound/lash )"
DEPEND="${RDEPEND}
	>=dev-lang/swig-1.3.0
	dev-util/pkgconfig
	doc? ( app-doc/doxygen virtual/latex-base )"

pkg_setup() {
	DOCS=( AUTHORS ChangeLog README TODO )

	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-multilib.patch \
		"${FILESDIR}"/${P}-numarray-gnuplot.patch

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_enable jack) \
		$(use_enable alsa) \
		$(use_enable lash)
}

src_compile() {
	default

	if use doc; then
		export VARTEXFONTS="${T}/fonts"
		cd "${S}"/doc
		doxygen user.cfg
		doxygen devel.cfg
		doxygen examples.cfg
	fi
}

src_install() {
	# `default` would be enough here if python.eclass supported EAPI=4
	emake DESTDIR="${D}" install || die
	dodoc "${DOCS[@]}"

	doman doc/*.1
	if use doc; then
		mv doc/user/html doc/user/user
		dohtml -r doc/user/user
		mv doc/devel/html doc/devel/devel
		dohtml -r doc/devel/devel
		mv doc/examples/html doc/examples/examples
		dohtml -r doc/examples/examples
	fi

	find "${ED}"usr -name '*.la' -exec rm -f {} +
}

pkg_postinst() { python_mod_optimize aubio; }
pkg_postrm() { python_mod_cleanup aubio; }