Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Patrick McLean (chutzpah)" <chutzpah@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in app-admin/salt: salt-2014.7.4.ebuild ChangeLog
Date: Mon, 30 Mar 2015 22:36:52
Message-Id: 20150330223649.E165914E04@oystercatcher.gentoo.org
1 chutzpah 15/03/30 22:36:49
2
3 Modified: ChangeLog
4 Added: salt-2014.7.4.ebuild
5 Log:
6 Version bump.
7
8 (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)
9
10 Revision Changes Path
11 1.57 app-admin/salt/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?rev=1.57&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?rev=1.57&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?r1=1.56&r2=1.57
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v
20 retrieving revision 1.56
21 retrieving revision 1.57
22 diff -u -r1.56 -r1.57
23 --- ChangeLog 17 Feb 2015 20:08:27 -0000 1.56
24 +++ ChangeLog 30 Mar 2015 22:36:49 -0000 1.57
25 @@ -1,6 +1,11 @@
26 # ChangeLog for app-admin/salt
27 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.56 2015/02/17 20:08:27 chutzpah Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.57 2015/03/30 22:36:49 chutzpah Exp $
30 +
31 +*salt-2014.7.4 (30 Mar 2015)
32 +
33 + 30 Mar 2015; Patrick McLean <chutzpah@g.o> +salt-2014.7.4.ebuild:
34 + Version bump.
35
36 17 Feb 2015; Patrick McLean <chutzpah@g.o> -salt-2014.7.0-r1.ebuild,
37 -salt-2014.7.1.ebuild:
38
39
40
41 1.1 app-admin/salt/salt-2014.7.4.ebuild
42
43 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-2014.7.4.ebuild?rev=1.1&view=markup
44 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-2014.7.4.ebuild?rev=1.1&content-type=text/plain
45
46 Index: salt-2014.7.4.ebuild
47 ===================================================================
48 # Copyright 1999-2015 Gentoo Foundation
49 # Distributed under the terms of the GNU General Public License v2
50 # $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-2014.7.4.ebuild,v 1.1 2015/03/30 22:36:49 chutzpah Exp $
51
52 EAPI=5
53 PYTHON_COMPAT=(python2_7)
54
55 inherit eutils distutils-r1 systemd
56
57 DESCRIPTION="Salt is a remote execution and configuration manager"
58 HOMEPAGE="http://saltstack.org/"
59
60 if [[ ${PV} == 9999* ]]; then
61 inherit git-r3
62 EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
63 EGIT_BRANCH="develop"
64 SRC_URI=""
65 KEYWORDS=""
66 else
67 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
68 KEYWORDS="~x86 ~amd64"
69 fi
70
71 LICENSE="Apache-2.0"
72 SLOT="0"
73 IUSE="api ldap libcloud libvirt gnupg keyring mako mongodb mysql nova"
74 IUSE+=" openssl redis selinux timelib raet +zeromq test"
75
76 RDEPEND="sys-apps/pciutils
77 dev-python/jinja[${PYTHON_USEDEP}]
78 >=dev-python/msgpack-0.3[${PYTHON_USEDEP}]
79 dev-python/pyyaml[${PYTHON_USEDEP}]
80 dev-python/markupsafe[${PYTHON_USEDEP}]
81 >=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
82 dev-python/setuptools[${PYTHON_USEDEP}]
83 libcloud? ( >=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}] )
84 mako? ( dev-python/mako[${PYTHON_USEDEP}] )
85 ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
86 openssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
87 libvirt? ( dev-python/libvirt-python[${PYTHON_USEDEP}] )
88 raet? (
89 dev-python/libnacl[${PYTHON_USEDEP}]
90 dev-python/ioflo[${PYTHON_USEDEP}]
91 dev-python/raet[${PYTHON_USEDEP}]
92 )
93 zeromq? (
94 >=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
95 >=dev-python/m2crypto-0.22.3[${PYTHON_USEDEP}]
96 dev-python/pycrypto[${PYTHON_USEDEP}]
97 )
98 api? (
99 || (
100 dev-python/cherrypy[${PYTHON_USEDEP}]
101 www-servers/tornado[${PYTHON_USEDEP}]
102 )
103 )
104 mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
105 keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
106 mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
107 redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
108 selinux? ( sec-policy/selinux-salt )
109 timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )
110 nova? ( >=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}] )
111 gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )"
112 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
113 test? (
114 dev-python/pip[${PYTHON_USEDEP}]
115 dev-python/virtualenv[${PYTHON_USEDEP}]
116 dev-python/timelib[${PYTHON_USEDEP}]
117 >=dev-python/SaltTesting-2015.2.16[${PYTHON_USEDEP}]
118 ${RDEPEND}
119 )"
120
121 DOCS=(README.rst AUTHORS)
122
123 REQUIRED_USE="|| ( raet zeromq )"
124
125 PATCHES=(
126 "${FILESDIR}/${PN}-2014.7.1-remove-pydsl-includes-test.patch"
127 )
128
129 python_prepare() {
130 # this test fails because it trys to "pip install distribute"
131 rm tests/unit/{modules,states}/zcbuildout_test.py
132 }
133
134 python_install_all() {
135 USE_SETUPTOOLS=1 distutils-r1_python_install_all
136
137 for s in minion master syndic $(use api && echo api); do
138 newinitd "${FILESDIR}"/${s}-initd-3 salt-${s}
139 newconfd "${FILESDIR}"/${s}-confd-1 salt-${s}
140 systemd_dounit "${FILESDIR}"/salt-${s}.service
141 done
142
143 insinto /etc/${PN}
144 doins -r conf/*
145 }
146
147 python_test() {
148 # testsuite likes lots of files
149 ulimit -n 3072
150
151 # using ${T} for the TMPDIR makes some tests needs paths that exceed PATH_MAX
152 USE_SETUPTOOLS=1 SHELL="/bin/bash" TMPDIR="/tmp" \
153 ${EPYTHON} tests/runtests.py \
154 --unit-tests --no-report --verbose || die "testing failed"
155 }
Report Message
Find on MARC Find on Google Groups