[gentoo-commits] gentoo-x86 commit in sys-cluster/gearmand: gearmand-0.34-r1.ebuild ChangeLog gearmand-0.34.ebuild gearmand-0.33.ebuild

[Diego Petteno (flameeyes)]

flameeyes    13/03/04 08:33:19

  Modified:             ChangeLog
  Added:                gearmand-0.34-r1.ebuild
  Removed:              gearmand-0.34.ebuild gearmand-0.33.ebuild
  Log:
  Remove old; bump to use autotools-utils and use sub-slot dependency on boost.
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.20                 sys-cluster/gearmand/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	22 Nov 2012 04:19:21 -0000	1.19
+++ ChangeLog	4 Mar 2013 08:33:18 -0000	1.20
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/gearmand
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v 1.19 2012/11/22 04:19:21 flameeyes Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/ChangeLog,v 1.20 2013/03/04 08:33:18 flameeyes Exp $
+
+*gearmand-0.34-r1 (04 Mar 2013)
+
+  04 Mar 2013; Diego E. Pettenò <flameeyes@g.o> +gearmand-0.34-r1.ebuild,
+  -files/gearmand-0.33+gcc-4.7.patch, -gearmand-0.33.ebuild,
+  -gearmand-0.34.ebuild:
+  Remove old; bump to use autotools-utils and use sub-slot dependency on boost.
 
   22 Nov 2012; Diego E. Pettenò <flameeyes@g.o> gearmand-0.34.ebuild:
   Depend on a multithread-safe version of boost if available.



1.1                  sys-cluster/gearmand/gearmand-0.34-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/gearmand-0.34-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/gearmand/gearmand-0.34-r1.ebuild?rev=1.1&content-type=text/plain

Index: gearmand-0.34-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/gearmand/gearmand-0.34-r1.ebuild,v 1.1 2013/03/04 08:33:18 flameeyes Exp $

EAPI=5

inherit flag-o-matic libtool autotools-utils

DESCRIPTION="Generic framework to farm out work to other machines"
HOMEPAGE="http://www.gearman.org/"
SRC_URI="http://launchpad.net/gearmand/trunk/${PV}/+download/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug tcmalloc +memcache drizzle sqlite tokyocabinet postgres"

RDEPEND="dev-libs/libevent
	>=dev-libs/boost-1.39:=[threads(+)]
	|| ( >=sys-apps/util-linux-2.16 <sys-libs/e2fsprogs-libs-1.41.8 )
	tcmalloc? ( dev-util/google-perftools )
	memcache? ( >=dev-libs/libmemcached-0.47 )
	drizzle? ( dev-db/drizzle )
	sqlite? ( dev-db/sqlite:3 )
	tokyocabinet? ( dev-db/tokyocabinet )
	postgres? ( >=dev-db/postgresql-base-9.0 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

pkg_setup() {
	enewuser gearmand -1 -1 /dev/null nogroup
}

src_configure() {
	local myeconfargs=(
		$(use_enable drizzle libdrizzle)
		$(use_enable memcache libmemcached)
		$(use_enable postgres libpq)
		$(use_enable tcmalloc)
		$(use_enable tokyocabinet libtokyocabinet)
		$(use_with sqlite sqlite3)
		--disable-mtmalloc
		--disable-static
	)

	# Don't ever use --enable-assert since configure.ac is broken, and
	# only does --disable-assert correctly.
	if use debug; then
		# Since --with-debug would turn off optimisations as well as
		# enabling debug, we just enable debug through the
		# preprocessor then.
		append-cppflags -DDEBUG
	fi

	autotools-utils_src_configure
}

src_test() {
	# Since libtool is stupid and doesn't discard /usr/lib64 from the
	# load path, we'd end up testing against the installed copy of
	# gearmand (bad).
	#
	# We thus cheat and "fix" the scripts by hand.
	sed -i -e '/LD_LIBRARY_PATH=/s|/usr/lib64:||' "${BUILD_DIR}"/tests/*_test \
		|| die "test fixing failed"

	autotools-utils_src_test
}

DOCS=( README AUTHORS ChangeLog )

src_install() {
	autotools-utils_src_install

	newinitd "${FILESDIR}"/gearmand.init.d.2 gearmand
	newconfd "${FILESDIR}"/gearmand.conf.d gearmand
}

pkg_postinst() {
	elog ""
	elog "Unless you set the PERSISTENT_TABLE option in"
	elog "/etc/conf.d/gearmand, Gearmand will use table 'queue'."
	elog "If such table doesn't exist, Gearmand will create it for you"
	elog ""
}