[gentoo-commits] gentoo-x86 commit in media-sound/picard: metadata.xml ChangeLog picard-0.12.1-r1.ebuild

[Justin Lecher (jlec)]

jlec        10/05/29 09:24:56

  Modified:             metadata.xml ChangeLog
  Added:                picard-0.12.1-r1.ebuild
  Log:
  Fix Python ABI compatibility #313965; added support for covert download #295922
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  media-sound/picard/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/picard/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	17 Nov 2009 23:35:31 -0000	1.5
+++ metadata.xml	29 May 2010 09:24:56 -0000	1.6
@@ -6,4 +6,5 @@
   written in Python. Picard Tagger is intended to be the next generation of
   tagger for MusicBrainz, with a focus on album oriented tagging as opposed to
   track based tagging and cross platform compatibility.</longdescription>
+<use><flag name='coverart'>Install plugin for direct coverart dowload</flag></use>
 </pkgmetadata>



1.25                 media-sound/picard/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	10 Mar 2010 09:26:24 -0000	1.24
+++ ChangeLog	29 May 2010 09:24:56 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/picard
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.24 2010/03/10 09:26:24 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.25 2010/05/29 09:24:56 jlec Exp $
+
+*picard-0.12.1-r1 (29 May 2010)
+
+  29 May 2010; Justin Lecher <jlec@g.o> +picard-0.12.1-r1.ebuild,
+  metadata.xml:
+  Fix Python ABI compatibility #313965; added support for covert download
+  #295922
 
   10 Mar 2010; Joseph Jezak <josejx@g.o> picard-0.12.1.ebuild:
   Marked ~ppc for bug #306453.



1.1                  media-sound/picard/picard-0.12.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/picard-0.12.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/picard/picard-0.12.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: picard-0.12.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/picard-0.12.1-r1.ebuild,v 1.1 2010/05/29 09:24:56 jlec Exp $

EAPI="3"

PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils

DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="true"

MY_P="${P/_/}"
DESCRIPTION="An improved rewrite/port of the Picard Tagger using Qt"
HOMEPAGE="http://musicbrainz.org/doc/PicardQt"
SRC_URI="
	http://ftp.musicbrainz.org/pub/musicbrainz/picard/${MY_P}.tar.gz
	coverart? ( http://users.musicbrainz.org/~outsidecontext/picard/plugins/coverart.py )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="cdda coverart ffmpeg nls"

DEPEND="
	dev-python/PyQt4[X]
	media-libs/mutagen
	cdda? ( >=media-libs/libdiscid-0.1.1 )
	ffmpeg? (
		media-video/ffmpeg
		>=media-libs/libofa-0.9.2 )"
RDEPEND="${DEPEND}"

# doesn't work with ebuilds
RESTRICT="test"

RESTRICT_PYTHON_ABIS="2.4 3.*"

S="${WORKDIR}/${MY_P}"

DOCS="AUTHORS.txt INSTALL.txt NEWS.txt"

pkg_setup() {
	if ! use ffmpeg; then
		ewarn "The 'ffmpeg' USE flag is disabled. Acoustic fingerprinting and"
		ewarn "recognition will not be available."
	fi
	if ! use cdda; then
		ewarn "The 'cdda' USE flag is disabled. CD index lookup and"
		ewarn "identification will not be available. You can get audio CD support"
		ewarn "by installing media-libs/libdiscid."
	fi
}

src_unpack() {
	unpack ${MY_P}.tar.gz
	if use coverart; then
		cp "${DISTDIR}"/coverart.py "${S}"/${PN}/plugins/coverart.py || die "Copy of coverart plugin failed"
	fi
}

src_configure() {
	configuration() {
	$(PYTHON) setup.py config || die "setup.py config failed"
	if ! use ffmpeg; then
		sed -i -e "s:\(^with-avcodec\ =\ \).*:\1False:" \
			-e "s:\(^with-libofa\ =\ \).*:\1False:" \
			build.cfg || die "sed failed"
	fi
	}
	python_execute_function -s configuration
}

src_compile() {
	distutils_src_compile $(use nls || echo "--disable-locales")
}

src_install() {
	distutils_src_install --disable-autoupdate --skip-build \
		$(use nls || echo "--disable-locales")

	doicon picard.ico || die 'doicon failed'
	domenu picard.desktop || die 'domenu failed'
}

pkg_postinst() {
	distutils_pkg_postinst
	echo
	ewarn "If you are upgrading Picard and it does not start"
	ewarn "try removing Picard's settings:"
	ewarn "	rm ~/.config/MusicBrainz/Picard.conf"
	elog
	elog "You should set the environment variable BROWSER to something like"
	elog "\"firefox '%s' &\" to let python know which browser to use."
	if use coverart; then
		ewarn "You have downloaded and installed the coverart downloader plugin."
		ewarn "If you expect it to work please enable it in Options->Plugins."
	fi
}