[gentoo-commits] repo/gentoo:master commit in: dev-python/requests/

[Michał Górny]

commit:     9d32b1ef2905393bc94516aa1deb7563ac2f7c6c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 17 07:19:53 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul 17 07:23:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d32b1ef

dev-python/requests: Bump to 2.26.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/requests/Manifest               |  1 +
 dev-python/requests/requests-2.26.0.ebuild | 53 ++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-python/requests/Manifest b/dev-python/requests/Manifest
index c3b2f9c1b31..afb9f28b3e7 100644
--- a/dev-python/requests/Manifest
+++ b/dev-python/requests/Manifest
@@ -1 +1,2 @@
 DIST requests-2.25.1.tar.gz 102161 BLAKE2B 1901ca3bb1eb7a6eb7689a81e01c1c23d3f359835507fda78de734162cbd8573b7640c9376cb50ed9397603d67d9a14624028573c2709086547f37993a959429 SHA512 ca6b0a257b448a999cade0ae173c29cddc9cfffb319d16fc3d051d3e1cd77161536e3cab279b3cba59c60d29d7864a9281c1fa1f689ce48d3bce2ca9f1cd8d45
+DIST requests-2.26.0.tar.gz 104433 BLAKE2B 49872a0602ab0e6b3838c4ff84d6611c5265dd584a1902b51d5903a2fc566b97f7a70973a9244adf190e9249bc6d1fa448a2164a31d125ab6b3dac172ae62e1c SHA512 c3397d77f0d2f1afb05661c4b98adad6c1ddaf360906254150b33ab0d9479fd306905bd6d61b8cf8becd9a40bdcf9b03542e8267c644ef19f03f44bfca0bc461

diff --git a/dev-python/requests/requests-2.26.0.ebuild b/dev-python/requests/requests-2.26.0.ebuild
new file mode 100644
index 00000000000..2d726cc2333
--- /dev/null
+++ b/dev-python/requests/requests-2.26.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="https://requests.readthedocs.io/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="socks5"
+
+RDEPEND="
+	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
+	dev-python/charset_normalizer[${PYTHON_USEDEP}]
+	<dev-python/idna-4[${PYTHON_USEDEP}]
+	<dev-python/urllib3-1.27[${PYTHON_USEDEP}]
+	socks5? ( >=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}] )
+"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# Internet
+		requests/__init__.py::requests
+		requests/api.py::requests.api.request
+		requests/models.py::requests.models.PreparedRequest
+		requests/sessions.py::requests.sessions.Session
+		tests/test_requests.py::TestRequests::test_https_warnings
+		tests/test_requests.py::TestTimeout::test_connect_timeout
+		tests/test_requests.py::TestTimeout::test_total_timeout_connect
+		# TODO: openssl?
+		tests/test_requests.py::TestRequests::test_pyopenssl_redirect
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}