[gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog metadata.xml libvirt-0.4.6.ebuild libvirt-0.4.4-r2.ebuild libvirt-0.4.4-r1.ebuild libvirt-0.3.3.ebuild libvirt-0.4.2.ebuild libvirt-0.1.4.ebuild libvirt-0.4.4.ebuild libvirt-0.1.7.ebuild libvirt-0.1.3.ebuild libvirt-0.2.3.ebuild

[Micheal Marineau (marineam)]

marineam    08/11/23 21:53:54

  Modified:             ChangeLog metadata.xml
  Added:                libvirt-0.4.6.ebuild libvirt-0.4.4-r2.ebuild
  Removed:              libvirt-0.4.4-r1.ebuild libvirt-0.3.3.ebuild
                        libvirt-0.4.2.ebuild libvirt-0.1.4.ebuild
                        libvirt-0.4.4.ebuild libvirt-0.1.7.ebuild
                        libvirt-0.1.3.ebuild libvirt-0.2.3.ebuild
  Log:
  Bump libvirt to 0.4.6 and fix a couple bugs.
  (Portage version: 2.1.4.5)

Revision  Changes    Path
1.17                 app-emulation/libvirt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	11 Aug 2008 13:52:02 -0000	1.16
+++ ChangeLog	23 Nov 2008 21:53:54 -0000	1.17
@@ -1,6 +1,19 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.16 2008/08/11 13:52:02 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.17 2008/11/23 21:53:54 marineam Exp $
+
+*libvirt-0.4.6 (23 Nov 2008)
+*libvirt-0.4.4-r2 (23 Nov 2008)
+
+  23 Nov 2008; Michael Marineau <marineam@g.o>
+  +files/libvirt-0.4.6-parallel-build-fix.patch,
+  +files/libvirt-0.4.6-qemu-img-name.patch, files/libvirtd.init,
+  metadata.xml, -libvirt-0.1.3.ebuild, -libvirt-0.1.4.ebuild,
+  -libvirt-0.1.7.ebuild, -libvirt-0.2.3.ebuild, -libvirt-0.3.3.ebuild,
+  -libvirt-0.4.2.ebuild, -libvirt-0.4.4.ebuild, -libvirt-0.4.4-r1.ebuild,
+  +libvirt-0.4.4-r2.ebuild, +libvirt-0.4.6.ebuild:
+  Fix bugs #233379 and #238008. Bump to 0.4.6, bug #239387.
+  Clean out lots of old versions.
 
   11 Aug 2008; Tiziano Müller <dev-zero@g.o> files/libvirtd.init:
   Removed bashism, added a progress-meter...... ;-)



1.7                  app-emulation/libvirt/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	28 Jul 2008 18:51:55 -0000	1.6
+++ metadata.xml	23 Nov 2008 21:53:54 -0000	1.7
@@ -10,6 +10,10 @@
 		<email>ramereth@g.o</email>
 		<name>Lance Albertson</name>
 	</maintainer>
+	<maintainer>
+		<email>marineam@g.o</email>
+		<name>Michael Marineau</name>
+	</maintainer>
 	<use>
 		<flag name='iscsi'>Add support for iSCSI (Internet SCSI) remote
 			storage</flag>



1.1                  app-emulation/libvirt/libvirt-0.4.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.4.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.4.6.ebuild?rev=1.1&content-type=text/plain

Index: libvirt-0.4.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.4.6.ebuild,v 1.1 2008/11/23 21:53:54 marineam Exp $

inherit eutils autotools

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi lvm kvm openvz parted qemu sasl selinux server xen" #policykit is in package.mask

DEPEND="sys-libs/readline
	sys-libs/ncurses
	>=dev-libs/libxml2-2.5
	>=net-libs/gnutls-1.0.25
	dev-lang/python
	sys-fs/sysfsutils
	net-misc/bridge-utils
	net-analyzer/netcat
	avahi? ( >=net-dns/avahi-0.6 )
	iscsi? ( sys-block/open-iscsi )
	kvm? ( app-emulation/kvm )
	lvm? ( sys-fs/lvm2 )
	openvz? ( sys-kernel/openvz-sources )
	parted? ( >=sys-apps/parted-1.8 )
	qemu? ( app-emulation/qemu )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( sys-libs/libselinux )
	server? ( net-dns/dnsmasq )
	xen? ( app-emulation/xen-tools app-emulation/xen )
	"
	#policykit? ( >=sys-auth/policykit-0.6 )

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/"${P}"-qemu-img-name.patch
	epatch "${FILESDIR}"/"${P}"-parallel-build-fix.patch
	eautoreconf
}

pkg_setup() {
	if ! use qemu && ! use xen && ! use openvz && ! use kvm ; then
		local msg="You must enable one of these USE flags: qemu xen openvz kvm"
		eerror "$msg"
		die "$msg"
	fi
}

src_compile() {
	local my_conf=""
	if use qemu || use kvm ; then
		# fix path for kvm-img but use qemu-img if the useflag is set
		my_conf="--with-qemu \
			$(use_with !qemu qemu-img-name kvm-img)"
	else
		my_conf="--without-qemu"
	fi

	econf \
		$(use_with avahi) \
		$(use_with iscsi storage-iscsi) \
		$(use_with lvm storage-lvm) \
		$(use_with openvz) \
		$(use_with parted storage-disk) \
		$(use_with sasl) \
		$(use_with selinux) \
		$(use_with server libvirtd) \
		$(use_with xen) \
		${my_conf} \
		--with-remote \
		--disable-iptables-lokkit \
		--with-remote-pid-file=/var/run/libvirtd.pid \
		|| die "econf failed"
		#$(use_with policykit) \
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}
	if use server ; then
		newinitd "${FILESDIR}"/libvirtd.init libvirtd
		newconfd "${FILESDIR}"/libvirtd.confd libvirtd
	fi
}



1.1                  app-emulation/libvirt/libvirt-0.4.4-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.4.4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.4.4-r2.ebuild?rev=1.1&content-type=text/plain

Index: libvirt-0.4.4-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.4.4-r2.ebuild,v 1.1 2008/11/23 21:53:54 marineam Exp $

inherit eutils autotools

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi lvm kvm openvz parted qemu sasl selinux server xen" #policykit is in package.mask

DEPEND="sys-libs/readline
	sys-libs/ncurses
	>=dev-libs/libxml2-2.5
	>=net-libs/gnutls-1.0.25
	dev-lang/python
	sys-fs/sysfsutils
	net-misc/bridge-utils
	net-analyzer/netcat
	avahi? ( >=net-dns/avahi-0.6 )
	iscsi? ( sys-block/open-iscsi )
	kvm? ( app-emulation/kvm )
	lvm? ( sys-fs/lvm2 )
	openvz? ( sys-kernel/openvz-sources )
	parted? ( >=sys-apps/parted-1.8 )
	qemu? ( app-emulation/qemu )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( sys-libs/libselinux )
	server? ( net-dns/dnsmasq )
	xen? ( app-emulation/xen-tools app-emulation/xen )
	"
	#policykit? ( >=sys-auth/policykit-0.6 )

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/"${P}"-kvm-cdrom-fix.patch

	# app-emulation/kvm renames its binaries with kvm-* prefixes, deal with it
	# in a sane manner for libvirt but use qemu-img if the useflag is set
	if use kvm && ! use qemu ; then
		epatch "${FILESDIR}"/"${P}"-binary-paths.patch
		epatch "${FILESDIR}"/"${P}"-capabilities-kvm-path.patch
	fi

	epatch "${FILESDIR}"/"${PN}"-0.4.6-parallel-build-fix.patch
	eautoreconf
}

pkg_setup() {
	if ! use qemu && ! use xen && ! use openvz && ! use kvm ; then
		local msg="You must enable one of these USE flags: qemu xen openvz kvm"
		eerror "$msg"
		die "$msg"
	fi
}

src_compile() {
	local my_conf=""
	if use qemu || use kvm ; then
		my_conf="--with-qemu \
			$(use_with !qemu qemu-img-name kvm-img)"
	else
		my_conf="--without-qemu"
	fi

	econf \
		$(use_with avahi) \
		$(use_with iscsi storage-iscsi) \
		$(use_with kvm qemu-kvm-path /usr/bin/kvm) \
		$(use_with lvm storage-lvm) \
		$(use_with openvz) \
		$(use_with parted storage-disk) \
		$(use_with sasl) \
		$(use_with selinux) \
		$(use_with server libvirtd) \
		$(use_with xen) \
		${my_conf} \
		--with-remote \
		--disable-iptables-lokkit \
		--with-remote-pid-file=/var/run/libvirtd.pid \
		|| die "econf failed"
		#$(use_with policykit) \
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}
	if use server ; then
		newinitd "${FILESDIR}"/libvirtd.init libvirtd
		newconfd "${FILESDIR}"/libvirtd.confd libvirtd
	fi
}