[gentoo-commits] repo/gentoo:master commit in: dev-python/plotly/

[Andrew Ammerlaan]

commit:     efa4b2c5f0ca02034411924817f3dfce8d5ca950
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 29 11:05:17 2023 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Sun Jan 29 11:44:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=efa4b2c5

dev-python/plotly: add 5.13.0

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/plotly/Manifest             |  1 +
 dev-python/plotly/plotly-5.13.0.ebuild | 98 ++++++++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index 8375fe3c18d1..bc5e16862131 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1 +1,2 @@
 DIST plotly-5.10.0.tar.gz 7600627 BLAKE2B cb83d2b14553b0336db098977a29e0417ce8f65ef5088bfa7fbd4ab5ee7cc561e3f3e32504604a402be395d8c46b0948379e9350dff37b225eba3298f2549cfd SHA512 f30f78ad8683d8b8ccd6a1c383772eddf6719fd47b4be693a72e9ae2c6d567fbf683e87aecc24dcd4c1fd89697366e510cfd93e6599d859554b687e6f6cfb416
+DIST plotly.py-5.13.0.gh.tar.gz 30683340 BLAKE2B 0e2c5638c766e5da6e2067d7be270576afed984b45deec0955fa10698d37bd082f3ebc568a8290c17554c672ef9e31cee81b0fae18b9f3249591fe62510ce5fd SHA512 c874b46ac43520519951aad55f93bfcfe03910873fd273f283fe16ae2a4150cfa35104be422c21b65785c77f468f084847278f76bce3d9179cc2a339809c42e3

diff --git a/dev-python/plotly/plotly-5.13.0.ebuild b/dev-python/plotly/plotly-5.13.0.ebuild
new file mode 100644
index 000000000000..504511612d27
--- /dev/null
+++ b/dev-python/plotly/plotly-5.13.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="https://plotly.com/python/"
+SRC_URI="https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz -> plotly.py-${PV}.gh.tar.gz"
+S="${WORKDIR}/plotly.py-${PV}/packages/python/${PN}"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		sci-libs/scikit-image[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.8.0-fix-versioneer-import.patch
+)
+
+EPYTEST_IGNORE=(
+	# Needs porting to newer numpy
+	_plotly_utils/tests/validators/test_integer_validator.py
+
+	# kaleido not packaged
+	plotly/tests/test_optional/test_kaleido
+
+	# plotly-orca not packaged
+	plotly/tests/test_orca
+)
+
+EPYTEST_DESELECT=(
+	# Also needs porting to newer numpy
+	plotly/tests/test_io/test_to_from_plotly_json.py::test_object_numpy_encoding
+
+	# kaleido not packaged
+	plotly/tests/test_orca/test_to_image.py::test_bytesio
+
+	# Fails if not already installed
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# Minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_path_collection
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# In python 3.11 the produced error is slightly different
+	plotly/tests/test_core/test_errors/test_dict_path_errors.py::test_described_subscript_error_on_type_error
+)
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	mkdir -p "${ED}"/etc/ || die
+	mv "${ED}"/usr/etc/jupyter "${ED}"/etc/ || die
+	rmdir "${ED}"/usr/etc || die
+}