[gentoo-commits] gentoo-x86 commit in net-misc/tor: tor-0.2.6.2_alpha.ebuild ChangeLog tor-0.2.6.1_alpha-r3.ebuild

[Anthony G. Basile (blueness)]

blueness    15/01/01 12:04:30

  Modified:             ChangeLog
  Added:                tor-0.2.6.2_alpha.ebuild
  Removed:              tor-0.2.6.1_alpha-r3.ebuild
  Log:
  Version bump alpha, remove older
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.457                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.457&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.457&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.456&r2=1.457

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.456
retrieving revision 1.457
diff -u -r1.456 -r1.457
--- ChangeLog	1 Jan 2015 11:35:25 -0000	1.456
+++ ChangeLog	1 Jan 2015 12:04:30 -0000	1.457
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.456 2015/01/01 11:35:25 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.457 2015/01/01 12:04:30 blueness Exp $
+
+*tor-0.2.6.2_alpha (01 Jan 2015)
+
+  01 Jan 2015; Anthony G. Basile <blueness@g.o>
+  +tor-0.2.6.2_alpha.ebuild, -tor-0.2.6.1_alpha-r3.ebuild:
+  Version bump alpha, remove older
 
   01 Jan 2015; Agostino Sarubbo <ago@g.o> tor-0.2.5.10-r3.ebuild:
   Stable for ppc64, wrt bug #533564



1.1                  net-misc/tor/tor-0.2.6.2_alpha.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.6.2_alpha.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.6.2_alpha.ebuild?rev=1.1&content-type=text/plain

Index: tor-0.2.6.2_alpha.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.6.2_alpha.ebuild,v 1.1 2015/01/01 12:04:30 blueness Exp $

EAPI="5"

inherit eutils flag-o-matic readme.gentoo systemd toolchain-funcs versionator user

MY_PV="$(replace_version_separator 4 -)"
MY_PF="${PN}-${MY_PV}"
DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI="https://www.torproject.org/dist/${MY_PF}.tar.gz
	https://archive.torproject.org/tor-package-archive/${MY_PF}.tar.gz"
S="${WORKDIR}/${MY_PF}"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="-bufferevents nat-pmp scrypt seccomp selinux stats tor-hardening transparent-proxy test upnp web"

DEPEND="dev-libs/openssl
	sys-libs/zlib
	dev-libs/libevent
	bufferevents? ( dev-libs/libevent[ssl] )
	nat-pmp? ( net-libs/libnatpmp )
	scrypt? ( app-crypt/libscrypt )
	seccomp? ( sys-libs/libseccomp )
	upnp? ( net-libs/miniupnpc )"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-tor )"

pkg_setup() {
	enewgroup tor
	enewuser tor -1 -1 /var/lib/tor tor
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.2.3.14_alpha-torrc.sample.patch
}

src_configure() {
	# Upstream isn't sure of all the user provided CFLAGS that
	# will break tor, but does recommend against -fstrict-aliasing.
	# We'll filter-flags them here as we encounter them.
	filter-flags -fstrict-aliasing

	econf \
		--disable-buf-freelists \
		--enable-asciidoc \
		--enable-mempools \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable stats instrument-downloads) \
		$(use_enable bufferevents) \
		$(use_enable nat-pmp) \
		$(use_enable scrypt libscrypt) \
		$(use_enable seccomp) \
		$(use_enable tor-hardening gcc-hardening) \
		$(use_enable tor-hardening linker-hardening) \
		$(use_enable transparent-proxy transparent) \
		$(use_enable upnp) \
		$(use_enable web tor2web-mode) \
		$(use_enable test unittests) \
		$(use_enable test coverage)
}

src_install() {
	readme.gentoo_create_doc

	newconfd "${FILESDIR}"/tor.confd tor
	newinitd "${FILESDIR}"/tor.initd-r7 tor
	systemd_dounit "${FILESDIR}/${PN}.service"
	systemd_dotmpfilesd "${FILESDIR}/${PN}.conf"

	emake DESTDIR="${D}" install

	keepdir /var/lib/tor

	dodoc README ChangeLog ReleaseNotes doc/HACKING

	fperms 750 /var/lib/tor
	fowners tor:tor /var/lib/tor

	insinto /etc/tor/
	newins "${FILESDIR}"/torrc-r1 torrc
}

pkg_postinst() {
	readme.gentoo_pkg_postinst

	if [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -eq 8 && $(gcc-micro-version) -ge 1 ]] ; then
		ewarn "Due to a bug in  >=gcc-4.8.1, compiling ${P} with -Os leads to an infinite"
		ewarn "loop.  See:"
		ewarn
		ewarn "    https://trac.torproject.org/projects/tor/ticket/10259"
		ewarn "    http://gcc.gnu.org/bugzilla/show_bug.cgi?id=59358"
		ewarn
	fi
}