[gentoo-commits] gentoo-x86 commit in app-admin/gkrellm: gkrellm-2.3.0.ebuild ChangeLog gkrellm-2.3.1.ebuild

[Jim Ramsay (lack)]

lack        08/02/28 15:17:04

  Modified:             gkrellm-2.3.0.ebuild ChangeLog
  Added:                gkrellm-2.3.1.ebuild
  Log:
  Version bump - 2.3.1 is released (Bug #209937)
  (Portage version: 2.1.4.1)

Revision  Changes    Path
1.9                  app-admin/gkrellm/gkrellm-2.3.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild?r1=1.8&r2=1.9

Index: gkrellm-2.3.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- gkrellm-2.3.0.ebuild	11 Dec 2007 08:56:16 -0000	1.8
+++ gkrellm-2.3.0.ebuild	28 Feb 2008 15:17:03 -0000	1.9
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild,v 1.8 2007/12/11 08:56:16 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.0.ebuild,v 1.9 2008/02/28 15:17:03 lack Exp $
 
 inherit eutils multilib toolchain-funcs
 
@@ -35,9 +35,9 @@
 	unpack ${A}
 	cd "${S}"
 
-	epatch "${FILESDIR}"/${P}-build.patch
-	epatch "${FILESDIR}"/${P}-Makefile.patch
-	use gnutls && epatch "${FILESDIR}"/${P}-gnutls.patch
+	epatch "${FILESDIR}"/${PN}-2.3-build.patch
+	epatch "${FILESDIR}"/${PN}-2.3-Makefile.patch
+	use gnutls && epatch "${FILESDIR}"/${PN}-2.3-gnutls.patch
 
 	sed -e 's:#user\tnobody:user\tgkrellmd:' \
 		-e 's:#group\tproc:group\tgkrellmd:' \



1.152                app-admin/gkrellm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?rev=1.152&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?rev=1.152&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/ChangeLog?r1=1.151&r2=1.152

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v
retrieving revision 1.151
retrieving revision 1.152
diff -u -r1.151 -r1.152
--- ChangeLog	19 Oct 2007 20:05:54 -0000	1.151
+++ ChangeLog	28 Feb 2008 15:17:03 -0000	1.152
@@ -1,6 +1,16 @@
 # ChangeLog for app-admin/gkrellm
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v 1.151 2007/10/19 20:05:54 armin76 Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/ChangeLog,v 1.152 2008/02/28 15:17:03 lack Exp $
+
+*gkrellm-2.3.1 (28 Feb 2008)
+
+  28 Feb 2008; Jim Ramsay <lack@g.o>
+  -files/gkrellm-2.3.0-Makefile.patch, -files/gkrellm-2.3.0-build.patch,
+  -files/gkrellm-2.3.0-gnutls.patch, +files/gkrellm-2.3-Makefile.patch,
+  +files/gkrellm-2.3-build.patch, +files/gkrellm-2.3-gnutls.patch,
+  files/gkrellmd, +files/gkrellmd.conf, gkrellm-2.3.0.ebuild,
+  +gkrellm-2.3.1.ebuild:
+  Version bump - 2.3.1 is released (Bug #209937)
 
   19 Oct 2007; Raúl Porcel <armin76@g.o> gkrellm-2.3.0.ebuild:
   alpha/ia64/sparc stable wrt #195522



1.1                  app-admin/gkrellm/gkrellm-2.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.1.ebuild?rev=1.1&content-type=text/plain

Index: gkrellm-2.3.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/gkrellm/gkrellm-2.3.1.ebuild,v 1.1 2008/02/28 15:17:03 lack Exp $

inherit eutils multilib toolchain-funcs

DESCRIPTION="Single process stack of various system monitors"
HOMEPAGE="http://www.gkrellm.net/"
SRC_URI="http://members.dslextreme.com/users/billw/${PN}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="hddtemp gnutls lm_sensors nls ssl X kernel_FreeBSD"

RDEPEND=">=dev-libs/glib-2
	hddtemp? ( app-admin/hddtemp )
	gnutls? ( net-libs/gnutls )
	lm_sensors? ( sys-apps/lm_sensors )
	nls? ( virtual/libintl )
	ssl? ( dev-libs/openssl )
	X? ( >=x11-libs/gtk+-2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

pkg_setup() {
	enewgroup gkrellmd
	enewuser gkrellmd -1 -1 -1 gkrellmd
	TARGET=
	use kernel_FreeBSD && TARGET="freebsd"
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-2.3-build.patch
	epatch "${FILESDIR}"/${PN}-2.3-Makefile.patch
	use gnutls && epatch "${FILESDIR}"/${PN}-2.3-gnutls.patch

	sed -e 's:#user\tnobody:user\tgkrellmd:' \
		-e 's:#group\tproc:group\tgkrellmd:' \
		-i server/gkrellmd.conf || die "sed gkrellmd.conf failed"

	sed -e "s:/usr/lib:/usr/$(get_libdir):" \
		-e "s:/usr/local/lib:/usr/local/$(get_libdir):" \
		-i src/${PN}.h || die "sed ${PN}.h failed"
}

src_compile() {
	if use X ; then
		emake ${TARGET} \
			CC="$(tc-getCC)" \
			INSTALLROOT=/usr \
			INCLUDEDIR=/usr/include/gkrellm2 \
			LOCALEDIR=/usr/share/locale \
			$(use nls || echo enable_nls=0) \
			$(use gnutls || echo without-gnutls=yes) \
			$(use lm_sensors || echo without-libsensors=yes) \
			$(use ssl || echo without-ssl=yes) \
			|| die "emake failed"
	else
		cd server
			emake ${TARGET} \
			CC="$(tc-getCC)" \
			$(use lm_sensors || echo without-libsensors=yes) \
			|| die "emake failed"
			fi
}

src_install() {
	if use X ; then
		emake install${TARGET:+_}${TARGET} \
			$(use nls || echo enable_nls=0) \
			INSTALLDIR="${D}"/usr/bin \
			INCLUDEDIR="${D}"/usr/include \
			LOCALEDIR="${D}"/usr/share/locale \
			PKGCONFIGDIR="${D}"/usr/$(get_libdir)/pkgconfig \
			MANDIR="${D}"/usr/share/man/man1 \
			|| die "emake install failed"
			dosym gkrellm /usr/bin/gkrellm2

			dohtml *.html

			newicon src/icon.xpm ${PN}.xpm
		make_desktop_entry ${PN} GKrellM ${PN}.xpm
	else
		dobin server/gkrellmd || die "dobin failed"

		insinto /usr/include/gkrellm2
		doins server/gkrellmd.h || die "doins failed"
	fi

	doinitd "${FILESDIR}"/gkrellmd || die "doinitd failed"
	doconfd "${FILESDIR}"/gkrellmd.conf || die "doconfd failed"

	insinto /etc
	doins server/gkrellmd.conf || die "doins failed"

	dodoc Changelog CREDITS README
}

pkg_postinst() {
	ewarn "The old executable name 'gkrellm2' is deprecated."
	ewarn "We have provided a compatible symlink for your convenience,"
	ewarn "but this is only temporary.  You should run this as just 'gkrellm'"
	ewarn "instead."
}



-- 
gentoo-commits@l.g.o mailing list