[gentoo-commits] gentoo-x86 commit in dev-libs/keybinder: keybinder-0.3.0-r201.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/11/30 14:36:58

  Modified:             ChangeLog
  Added:                keybinder-0.3.0-r201.ebuild
  Log:
  Convert to python-single-r1. Use proper gtk-doc location.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.17                 dev-libs/keybinder/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/keybinder/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/keybinder/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/keybinder/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/keybinder/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	28 Nov 2012 09:48:45 -0000	1.16
+++ ChangeLog	30 Nov 2014 14:36:58 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/keybinder
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/keybinder/ChangeLog,v 1.16 2012/11/28 09:48:45 ssuominen Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/keybinder/ChangeLog,v 1.17 2014/11/30 14:36:58 mgorny Exp $
+
+*keybinder-0.3.0-r201 (30 Nov 2014)
+
+  30 Nov 2014; Michał Górny <mgorny@g.o> +keybinder-0.3.0-r201.ebuild:
+  Convert to python-single-r1. Use proper gtk-doc location.
 
   28 Nov 2012; Samuli Suominen <ssuominen@g.o>
   keybinder-0.3.0-r200.ebuild, keybinder-0.3.0-r300.ebuild:



1.1                  dev-libs/keybinder/keybinder-0.3.0-r201.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild?rev=1.1&content-type=text/plain

Index: keybinder-0.3.0-r201.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/keybinder/keybinder-0.3.0-r201.ebuild,v 1.1 2014/11/30 14:36:58 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit eutils python-single-r1

DESCRIPTION="A library for registering global keyboard shortcuts"
HOMEPAGE="http://kaizer.se/wiki/keybinder/"
SRC_URI="http://kaizer.se/publicfiles/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86"
IUSE="+introspection lua python"

RDEPEND=">=x11-libs/gtk+-2.20:2
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXrender
	introspection? ( dev-libs/gobject-introspection )
	lua? ( >=dev-lang/lua-5.1 )
	python? ( ${PYTHON_DEPS}
		>=dev-python/pygobject-2.15.3:2[${PYTHON_USEDEP}]
		>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS="AUTHORS NEWS README"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_configure() {
	local myconf
	use lua || myconf='--disable-lua'

	econf \
		$(use_enable introspection) \
		$(use_enable python) \
		${myconf}
}

src_install() {
	default
	prune_libtool_files --all
}