[gentoo-commits] gentoo-x86 commit in net-analyzer/pmacct: ChangeLog pmacct-0.12.5.ebuild

[Jeroen Roovers (jer)]

jer         10/12/29 16:57:29

  Modified:             ChangeLog
  Added:                pmacct-0.12.5.ebuild
  Log:
  Version bump. Set sizeof(sin6_addr) instead of hardcoded value (bug #340147).
  
  (Portage version: 2.2.0_alpha10/cvs/Linux i686)

Revision  Changes    Path
1.73                 net-analyzer/pmacct/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?rev=1.73&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?rev=1.73&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?r1=1.72&r2=1.73

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v
retrieving revision 1.72
retrieving revision 1.73
diff -u -r1.72 -r1.73
--- ChangeLog	16 Oct 2010 14:01:10 -0000	1.72
+++ ChangeLog	29 Dec 2010 16:57:29 -0000	1.73
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/pmacct
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v 1.72 2010/10/16 14:01:10 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v 1.73 2010/12/29 16:57:29 jer Exp $
+
+*pmacct-0.12.5 (29 Dec 2010)
+
+  29 Dec 2010; Jeroen Roovers <jer@g.o> +pmacct-0.12.5.ebuild,
+  +files/pmacct-0.12.5-sin6_addr.patch:
+  Version bump. Set sizeof(sin6_addr) instead of hardcoded value (bug #340147).
 
   16 Oct 2010; Brent Baude <ranger@g.o> pmacct-0.12.2.ebuild:
   stable ppc, bug 339280



1.1                  net-analyzer/pmacct/pmacct-0.12.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.5.ebuild?rev=1.1&content-type=text/plain

Index: pmacct-0.12.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.5.ebuild,v 1.1 2010/12/29 16:57:29 jer Exp $

EAPI="2"

inherit eutils toolchain-funcs

DESCRIPTION="A network tool to gather IP traffic information"
HOMEPAGE="http://www.pmacct.net/"
SRC_URI="http://www.pmacct.net/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="64bit debug ipv6 mysql postgres sqlite threads ulog"

RDEPEND="net-libs/libpcap
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	sqlite? ( =dev-db/sqlite-3* )"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-0.12.0-gentoo.patch \
		"${FILESDIR}"/${PN}-0.12.5-sin6_addr.patch
}

src_configure() {
	tc-export CC
	econf \
		$(use_enable 64bit) \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable sqlite sqlite3) \
		$(use_enable threads) \
		$(use_enable ulog) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc ChangeLog CONFIG-KEYS EXAMPLES FAQS KNOWN-BUGS README UPGRADE \
		docs/SIGNALS docs/PLUGINS docs/INTERNALS TODO TOOLS \
		|| die "dodoc failed"

	for dirname in examples sql; do
		docinto ${dirname}
		dodoc ${dirname}/* || die "dodoc ${dirname} failed"
	done

	newinitd "${FILESDIR}"/pmacctd-init.d pmacctd || die "newinitd failed"
	newconfd "${FILESDIR}"/pmacctd-conf.d pmacctd || die "newconfd failed"

	insinto /etc
	newins "${S}/examples/pmacctd-imt.conf.example" pmacctd.conf || \
		die "newins failed"
}