[gentoo-commits] repo/gentoo:master commit in: dev-java/bcpg/

[Patrice Clement]

commit:     f299005cdbcbb47a29e1ac63052491fc32a5aa7c
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 24 14:01:32 2018 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Apr 25 07:21:32 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f299005c

dev-java/bcpg: EAPI 6 bump.

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 dev-java/bcpg/bcpg-1.52-r2.ebuild | 73 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/dev-java/bcpg/bcpg-1.52-r2.ebuild b/dev-java/bcpg/bcpg-1.52-r2.ebuild
new file mode 100644
index 00000000000..a819a8dcd7e
--- /dev/null
+++ b/dev-java/bcpg/bcpg-1.52-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_P="${PN}-jdk15on-${PV/./}"
+
+DESCRIPTION="Java cryptography APIs"
+HOMEPAGE="http://www.bouncycastle.org/java.html"
+SRC_URI="http://polydistortion.net/bc/download/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="1.52"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+# Tests are currently broken. Appears to need older version of bcprov; but
+# since bcprov is not slotted, this can cause conflicts.  Needs further
+# investigation; though, only a small part has tests and there are no tests for
+# bcpg itself.
+RESTRICT="test"
+
+CDEPEND="dev-java/bcprov:${SLOT}"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6
+	test? ( dev-java/ant-junit:0 )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+S="${WORKDIR}/${MY_P}"
+
+JAVA_GENTOO_CLASSPATH="bcprov-${SLOT}"
+
+src_unpack() {
+	default
+	cd "${S}" || die
+	unpack ./src.zip
+}
+
+src_prepare() {
+	default
+	if ! use test; then
+		local RM_TEST_FILES=(
+			org/bouncycastle/openpgp/test
+			org/bouncycastle/openpgp/examples/test
+		)
+		rm -rv "${RM_TEST_FILES[@]}" || die
+	fi
+}
+
+src_compile() {
+	java-pkg-simple_src_compile
+}
+
+src_test() {
+	local cp="${PN}.jar:bcprov.jar:junit.jar"
+	local pkg="org.bouncycastle"
+	java -cp ${cp} ${pkg}.openpgp.test.AllTests | tee openpgp.tests
+	grep -q FAILURES *.tests && die "Tests failed."
+}
+
+src_install() {
+	einstalldocs
+	java-pkg-simple_src_install
+	use source && java-pkg_dosrc org
+}