[gentoo-commits] gentoo-x86 commit in games-roguelike/stone-soup: metadata.xml stone-soup-0.14.2.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/08/28 20:17:02

  Modified:             metadata.xml ChangeLog
  Added:                stone-soup-0.14.2.ebuild
  Log:
  version bump, introduce luajit USE flag
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.4                  games-roguelike/stone-soup/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	27 Aug 2013 13:36:10 -0000	1.3
+++ metadata.xml	28 Aug 2014 20:17:02 -0000	1.4
@@ -7,14 +7,17 @@
 		<name>Julian Ospald</name>
 	</maintainer>
 	<upstream>
-        <changelog>http://crawl.develz.org/main/0.12.2.txt</changelog>
         <doc lang="en">http://crawl.develz.org/wordpress/documentation</doc>
         <bugs-to>https://crawl.develz.org/mantis/main_page.php</bugs-to>
 	</upstream>
 	<use>
+		<flag name='luajit'>Use <pkg>dev-lang/luajit</pkg> as
+			scripting backend instead of <pkg>dev-lang/lua</pkg>.</flag>
 		<flag name='tiles'>Enable for graphical (tiled) build.
+			(can be enabled on top of ncurses)
 		</flag>
-		<flag name='ncurses'>Enable for console based build (uses ncurses).
+		<flag name='ncurses'>Enable for console (uses ncurses) based build.
+			(can be enabled on top of tiles)
 		</flag>
 	</use>
 	<longdescription lang="en">



1.35                 games-roguelike/stone-soup/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	19 Aug 2014 21:24:27 -0000	1.34
+++ ChangeLog	28 Aug 2014 20:17:02 -0000	1.35
@@ -1,6 +1,12 @@
 # ChangeLog for games-roguelike/stone-soup
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v 1.34 2014/08/19 21:24:27 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v 1.35 2014/08/28 20:17:02 hasufell Exp $
+
+*stone-soup-0.14.2 (28 Aug 2014)
+
+  28 Aug 2014; Julian Ospald <hasufell@g.o> +stone-soup-0.14.2.ebuild,
+  +files/stone-soup-0.14.2-build.patch, metadata.xml:
+  version bump, introduce luajit USE flag
 
   19 Aug 2014; Julian Ospald <hasufell@g.o> -stone-soup-0.11.2.ebuild,
   -stone-soup-0.12.2.ebuild, -stone-soup-0.12.3.ebuild,



1.1                  games-roguelike/stone-soup/stone-soup-0.14.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.14.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.14.2.ebuild?rev=1.1&content-type=text/plain

Index: stone-soup-0.14.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.14.2.ebuild,v 1.1 2014/08/28 20:17:02 hasufell Exp $

## TODO
# add sound support (no build switch, no sound files)

# check if luajit works

# cross compiling is severly broken

EAPI=5
VIRTUALX_REQUIRED="manual"
inherit eutils gnome2-utils virtualx toolchain-funcs games

MY_P="stone_soup-${PV}"
DESCRIPTION="Dungeon Crawl Stone Soup is a role-playing roguelike game of exploration and treasure-hunting in dungeons"
HOMEPAGE="http://crawl.develz.org/wordpress/"
SRC_URI="mirror://sourceforge/crawl-ref/Stone%20Soup/${PV}/${MY_P}-nodeps.tar.xz
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.png
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.svg"

# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
# Public Domain|CC0: most of tiles
# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug luajit ncurses test +tiles"
# test is broken
# see https://crawl.develz.org/mantis/view.php?id=6121
#RESTRICT="!debug? ( test )"
RESTRICT="test"

RDEPEND="
	dev-db/sqlite:3
	luajit? ( >=dev-lang/luajit-2.0.0 )
	!luajit? ( >=dev-lang/lua-5.1.0[deprecated] )
	sys-libs/zlib
	!ncurses? ( !tiles? ( sys-libs/ncurses ) )
	ncurses? ( sys-libs/ncurses )
	tiles? (
		media-fonts/dejavu
		media-libs/freetype:2
		media-libs/libpng:0
		media-libs/libsdl[X,opengl,video]
		media-libs/sdl-image[png]
		virtual/glu
		virtual/opengl
	)"
DEPEND="${RDEPEND}
	dev-lang/perl
	sys-devel/flex
	virtual/pkgconfig
	virtual/yacc
	tiles? (
		sys-libs/ncurses
		test? ( ${VIRTUALX_DEPEND} )
	)"

S=${WORKDIR}/${MY_P}/source
S_TEST=${WORKDIR}/${MY_P}_test/source

pkg_setup() {
	games_pkg_setup
	if use !ncurses && use !tiles ; then
		ewarn "Neither ncurses nor tiles frontend"
		ewarn "selected, choosing ncurses only."
		ewarn "Note that you can also enable both."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch

#	if use test ; then
#		cp -av "${WORKDIR}/${MY_P}" "${WORKDIR}/${MY_P}_test" \
#			|| die "setting up test-dir failed"
#	fi
}

src_compile() {
	export HOSTCXX=$(tc-getBUILD_CXX)

	# leave DATADIR at the top
	myemakeargs=(
		USE_LUAJIT=$(usex luajit "yes" "")
		DATADIR="${GAMES_DATADIR}/${PN}"
		V=1
		prefix="${GAMES_PREFIX}"
		SAVEDIR="~/.crawl"
		$(usex debug "FULLDEBUG=y DEBUG=y" "")
		CFOPTIMIZE="${CXXFLAGS}"
		LDFLAGS="${LDFLAGS}"
		MAKEOPTS="${MAKEOPTS}"
		AR="$(tc-getAR)"
		RANLIB="$(tc-getRANLIB)"
		CC="$(tc-getCC)"
		CXX="$(tc-getCXX)"
		PKGCONFIG="$(tc-getPKG_CONFIG)"
		STRIP=touch
	)

	if use ncurses || (use !ncurses && use !tiles) ; then
		emake "${myemakeargs[@]}"
		# move it in case we build both variants
		use tiles && { mv crawl "${WORKDIR}"/crawl-ncurses || die ;}
	fi

	if use tiles ; then
		emake clean
		emake "${myemakeargs[@]}" "TILES=y"
	fi

	# for test to work we need to compile with unset DATADIR
#	if use test ; then
#		emake ${myemakeargs[@]:1} -C "${S_TEST}"
#	fi
}

src_install() {
	emake "${myemakeargs[@]}" $(usex tiles "TILES=y" "") DESTDIR="${D}" prefix_fp="" bin_prefix="${D}${GAMES_BINDIR}" install
	[[ -e "${WORKDIR}"/crawl-ncurses ]] && dogamesbin "${WORKDIR}"/crawl-ncurses

	# don't relocate docs, needed at runtime
	rm -rf "${D}${GAMES_DATADIR}"/${PN}/docs/license
	dodoc "${WORKDIR}"/${MY_P}/README.{txt,pdf}

	# icons and menu for graphical build
	if use tiles ; then
		doicon -s 48 "${DISTDIR}"/${PN}.png
		doicon -s scalable "${DISTDIR}"/${PN}.svg
		make_desktop_entry crawl
	fi

	prepgamesdirs
}

src_test() {
	$(usex tiles "X" "")emake "${myemakeargs[@]:1}" -C "${S_TEST}" test
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update

	if use tiles && use ncurses ; then
		elog "Since you have enabled both tiles and ncurses frontends"
		elog "the ncurses binary is called 'crawl-ncurses' and the"
		elog "tiles binary is called 'crawl'."
	fi
}

pkg_postrm() {
	gnome2_icon_cache_update
}