[gentoo-commits] repo/gentoo:master commit in: app-emacs/elpy/

[Maciej Barć]

commit:     a6a19b5bc222be2cc70ba3238337c0db1ff8f253
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 31 19:23:09 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed Aug 31 19:26:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6a19b5b

app-emacs/elpy: bump to 1.35.0_p20220627

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/elpy/Manifest                     |  1 +
 app-emacs/elpy/elpy-1.35.0_p20220627.ebuild | 85 +++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/app-emacs/elpy/Manifest b/app-emacs/elpy/Manifest
index 281c4c88caff..81e5ebbc78e0 100644
--- a/app-emacs/elpy/Manifest
+++ b/app-emacs/elpy/Manifest
@@ -1 +1,2 @@
 DIST elpy-1.35.0_p20220321.tar.gz 177145 BLAKE2B 6362a68efc5997c3d0e26e22c6fe563e1fdba5e6f3a9e1e3c1b53bef8320cc4ac0f929edd177b492a5f2e622c265aeb23d34df8db8ae67bd9a2e48e00adc7c25 SHA512 e8cf579effa0a0bc8f3c05001341b96fd134f8f08c16d95d83200ad94a942e3f60ef4ee4186758a2810de2ca58ee41e7119bc84a7535f28665ec7dad29b07db0
+DIST elpy-1.35.0_p20220627.tar.gz 177246 BLAKE2B ded88f89949683000c9be606f3b5d2fc65a943c97e0369505713ecbd4f595a43a7ce560b699ebbdfd4a756703c5fa8fb21af5b4e8a1aa6dbb8a55fe4b7dcc468 SHA512 b9a4588eb83edef69661568b936e278621abad316ae160a00737c546b5eb26abd8ac089b369be212abbe16b66b590d9df73986995d36201c1010da7dc9706f79

diff --git a/app-emacs/elpy/elpy-1.35.0_p20220627.ebuild b/app-emacs/elpy/elpy-1.35.0_p20220627.ebuild
new file mode 100644
index 000000000000..7fc19d5e0d3e
--- /dev/null
+++ b/app-emacs/elpy/elpy-1.35.0_p20220627.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+H=de31d30003c515c25ff7bfd3a361c70c298f78bb
+
+DISTUTILS_SINGLE_IMPL=ON
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+NEED_EMACS=24.4
+
+inherit distutils-r1 elisp
+
+DESCRIPTION="Emacs Python Development Environment"
+HOMEPAGE="https://github.com/jorgenschaefer/elpy/"
+SRC_URI="https://github.com/jorgenschaefer/${PN}/archive/${H}.tar.gz
+			-> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${H}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-emacs/company-mode
+	app-emacs/highlight-indentation
+	app-emacs/pyvenv
+	app-emacs/s
+	app-emacs/yasnippet
+	$(python_gen_cond_dep 'dev-python/flake8[${PYTHON_USEDEP}]')
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/autopep8[${PYTHON_USEDEP}]
+			dev-python/jedi[${PYTHON_USEDEP}]
+			dev-python/yapf[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DOCS=( CONTRIBUTING.rst README.rst )
+PATCHES=(
+	"${FILESDIR}"/${PN}-elpy.el-yas-snippet-dirs.patch
+	"${FILESDIR}"/${PN}-elpy-rpc.el-elpy-rpc-pythonpath.patch
+)
+SITEFILE="50${PN}-gentoo.el"
+
+distutils_enable_sphinx docs --no-autodoc
+distutils_enable_tests unittest
+
+pkg_setup() {
+	elisp_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm elpy/tests/test_black.py || die
+
+	sed -i "s|@SITEETC@|${EPREFIX}${SITEETC}/${PN}|" ${PN}.el || die
+	sed -i "s|@PYTHONLIB@|${EPREFIX}/usr/lib/${EPYTHON}|" ${PN}-rpc.el || die
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	elisp_src_compile
+}
+
+src_test() {
+	distutils-r1_src_test
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	elisp_src_install
+	insinto ${SITEETC}/${PN}
+	doins -r snippets
+}