[gentoo-commits] gentoo-x86 commit in sys-auth/munge: ChangeLog munge-0.5.11.ebuild

[Justin Bronder (jsbronder)]

jsbronder    15/06/24 14:54:25

  Modified:             ChangeLog
  Added:                munge-0.5.11.ebuild
  Log:
  sys-cluster/openmpi:  bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 4D7043C9)

Revision  Changes    Path
1.23                 sys-auth/munge/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/munge/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/munge/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/munge/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/munge/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	1 Mar 2014 22:38:37 -0000	1.22
+++ ChangeLog	24 Jun 2015 14:54:25 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/munge
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/munge/ChangeLog,v 1.22 2014/03/01 22:38:37 mgorny Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/munge/ChangeLog,v 1.23 2015/06/24 14:54:25 jsbronder Exp $
+
+*munge-0.5.11 (24 Jun 2015)
+
+  24 Jun 2015; Justin Bronder <jsbronder@g.o> +munge-0.5.11.ebuild,
+  +files/fixed-recursive-use-of-make-in-makefiles.patch:
+  Bump (#551136), thanks to Brendan Horan for the bump and the patch
 
   01 Mar 2014; Michał Górny <mgorny@g.o> munge-0.5.10-r1.ebuild:
   Update libgcrypt dep to use slot :0.



1.1                  sys-auth/munge/munge-0.5.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/munge/munge-0.5.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/munge/munge-0.5.11.ebuild?rev=1.1&content-type=text/plain

Index: munge-0.5.11.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/munge/munge-0.5.11.ebuild,v 1.1 2015/06/24 14:54:25 jsbronder Exp $

EAPI=5
inherit autotools eutils user

DESCRIPTION="An authentication service for creating and validating credentials"
HOMEPAGE="https://github.com/dun/munge"
SRC_URI="https://github.com/dun/munge/releases/download/munge-${PV}/munge-${PV}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"

IUSE="gcrypt"

DEPEND="app-arch/bzip2
	sys-libs/zlib
	gcrypt? ( dev-libs/libgcrypt:0 )
	!gcrypt? ( dev-libs/openssl:0 )"
RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup munge
	enewuser munge -1 -1 /var/lib/munge munge
}

src_prepare() {
	# Accepted upstream, https://github.com/dun/munge/pull/40
	epatch "${FILESDIR}"/fixed-recursive-use-of-make-in-makefiles.patch

	eautoreconf
}

src_configure() {
	econf \
		--localstatedir=/var \
		--with-crypto-lib=$(usex gcrypt libgcrypt openssl)
}

src_install() {
	local d

	default

	# 450830
	if [ -d "${D}"/var/run ]; then
		rm -rf "${D}"/var/run || die
	fi

	diropts -o munge -g munge -m700
	dodir /etc/munge

	for d in "init.d" "default" "sysconfig"; do
		if [ -d "${D}"/etc/${d} ]; then
			rm -r "${D}"/etc/${d} || die
		fi
	done

	newconfd "${FILESDIR}"/${PN}d.confd ${PN}d
	newinitd "${FILESDIR}"/${PN}d.initd ${PN}d
}