[gentoo-commits] gentoo-x86 commit in mail-client/evolution: evolution-2.28.1.ebuild metadata.xml ChangeLog evolution-2.26.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/10/29 23:16:37

  Modified:             metadata.xml ChangeLog
  Added:                evolution-2.28.1.ebuild
  Removed:              evolution-2.26.2.ebuild
  Log:
  New version for GNOME 2.28. Clean up old revision.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 mail-client/evolution/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/metadata.xml?r1=1.9&r2=1.10

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/metadata.xml,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- metadata.xml	23 May 2009 22:31:53 -0000	1.9
+++ metadata.xml	29 Oct 2009 23:16:36 -0000	1.10
@@ -18,7 +18,7 @@
 		<flag name="networkmanager">Allows Evolution to automagically toggle
 			online/offline mode by talking to <pkg>net-misc/networkmanager</pkg>
 			and getting the current network state</flag>
-		<flag name="pst">Build optional plugin for PST file format import</flag>
+		<!-- <flag name="pst">Build optional plugin for PST file format import</flag> -->
 		<flag name="pda">Enable support for syncing Evolution Calendar and
 			Addressbooks with PDAs using <pkg>app-pda/gnome-pilot</pkg> and
 			<pkg>app-pda/gnome-pilot-conduit</pkg></flag>



1.279                mail-client/evolution/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.279&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.279&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/ChangeLog?r1=1.278&r2=1.279

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v
retrieving revision 1.278
retrieving revision 1.279
diff -u -r1.278 -r1.279
--- ChangeLog	27 Oct 2009 10:31:59 -0000	1.278
+++ ChangeLog	29 Oct 2009 23:16:36 -0000	1.279
@@ -1,6 +1,14 @@
 # ChangeLog for mail-client/evolution
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.278 2009/10/27 10:31:59 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.279 2009/10/29 23:16:36 eva Exp $
+
+*evolution-2.28.1 (29 Oct 2009)
+
+  29 Oct 2009; Gilles Dartiguelongue <eva@g.o>
+  -evolution-2.26.2.ebuild, +files/evolution-2.28.0-automagic-plugins.patch,
+  +files/evolution-2.28.0-delete-key.patch, +evolution-2.28.1.ebuild,
+  metadata.xml:
+  New version for GNOME 2.28. Clean up old revision.
 
   27 Oct 2009; Mounir Lamouri <volkmar@g.o> evolution-2.26.2.ebuild:
   Re-Keywording for ppc, bug 271002



1.1                  mail-client/evolution/evolution-2.28.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/evolution-2.28.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/evolution/evolution-2.28.1.ebuild?rev=1.1&content-type=text/plain

Index: evolution-2.28.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.28.1.ebuild,v 1.1 2009/10/29 23:16:36 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools gnome2 flag-o-matic python

DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="GPL-2 FDL-1.1"
SLOT="2.0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="crypt dbus hal kerberos krb4 ldap mono networkmanager nntp pda profile python ssl gstreamer exchange"
# pst

# Pango dependency required to avoid font rendering problems
# We need a graphical pinentry frontend to be able to ask for the GPG
# password from inside evolution, bug 160302
RDEPEND=">=dev-libs/glib-2.20
	>=x11-libs/gtk+-2.16
	>=gnome-extra/evolution-data-server-2.26.3
	>=x11-themes/gnome-icon-theme-2.20
	>=gnome-base/libbonobo-2.20.3
	>=gnome-base/libbonoboui-2.4.2
	>=gnome-extra/gtkhtml-3.27.90
	>=gnome-base/gconf-2
	>=gnome-base/libglade-2
	>=gnome-base/libgnomecanvas-2
	>=gnome-base/libgnomeui-2
	>=dev-libs/libxml2-2.7.3
	>=dev-libs/libgweather-2.25.3
	>=x11-misc/shared-mime-info-0.22
	>=gnome-base/gnome-desktop-2.26.0
	dbus? ( >=dev-libs/dbus-glib-0.74 )
	hal? ( >=sys-apps/hal-0.5.4 )
	x11-libs/libnotify
	pda? (
		>=app-pda/gnome-pilot-2.0.15
		>=app-pda/gnome-pilot-conduits-2 )
	dev-libs/atk
	ssl? (
		>=dev-libs/nspr-4.6.1
		>=dev-libs/nss-3.11 )
	networkmanager? ( >=net-misc/networkmanager-0.7 )
	>=net-libs/libsoup-2.4
	kerberos? ( virtual/krb5 )
	krb4? ( app-crypt/mit-krb5[krb4] )
	>=gnome-base/orbit-2.9.8
	crypt? ( || (
				  ( >=app-crypt/gnupg-2.0.1-r2
					|| ( app-crypt/pinentry[gtk] app-crypt/pinentry[qt3] ) )
				  =app-crypt/gnupg-1.4* ) )
	ldap? ( >=net-nds/openldap-2 )
	mono? ( >=dev-lang/mono-1 )
	python? ( >=dev-lang/python-2.4 )
	gstreamer? (
		>=media-libs/gstreamer-0.10
		>=media-libs/gst-plugins-base-0.10 )"
# Disabled until API stabilizes
#	pst? ( >=net-mail/libpst-0.6.41 )

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.16
	>=dev-util/intltool-0.35.5
	sys-devel/gettext
	sys-devel/bison
	app-text/scrollkeeper
	>=gnome-base/gnome-common-2.12.0
	>=app-text/gnome-doc-utils-0.9.1"

PDEPEND="exchange? ( >=gnome-extra/evolution-exchange-2.26.1 )"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
ELTCONF="--reverse-deps"

pkg_setup() {
	G2CONF="${G2CONF}
		--without-kde-applnk-path
		--enable-plugins=experimental
		--with-weather
		$(use_enable ssl nss)
		$(use_enable ssl smime)
		$(use_enable mono)
		$(use_enable nntp)
		$(use_enable networkmanager nm)
		$(use_enable dbus)
		$(use_enable gstreamer audio-inline)
		$(use_enable exchange)
		--disable-pst-import
		$(use_enable pda pilot-conduits)
		$(use_enable profile profiling)
		$(use_enable python)
		$(use_with ldap openldap)
		$(use_with kerberos krb5 /usr)
		$(use_with krb4 krb4 /usr)"

	# dang - I've changed this to do --enable-plugins=experimental.  This will
	# autodetect new-mail-notify and exchange, but that cannot be helped for the
	# moment.  They should be changed to depend on a --enable-<foo> like mono
	# is.  This cleans up a ton of crap from this ebuild.
}

src_prepare() {
	gnome2_src_prepare

	# Fix timezone offsets on fbsd.  bug #183708
	# FIXME: bsd needs to be more active at pushing stuff upstream
	#epatch "${FILESDIR}/${PN}-2.21.3-fbsd.patch"

	# Fix delete keyboard shortcut, bug #????
	epatch "${FILESDIR}/${PN}-2.28.0-delete-key.patch"

	# Fix multiple automagic plugins, bug #204300 & bug #271451
	epatch "${FILESDIR}/${PN}-2.28.0-automagic-plugins.patch"

	# FIXME: Fix compilation flags crazyness
	sed 's/CFLAGS="$CFLAGS $WARNING_FLAGS"//' \
		-i configure.ac configure || die "sed 1 failed"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf

	# Use NSS/NSPR only if 'ssl' is enabled.
	if use ssl ; then
		sed -i -e "s|mozilla-nss|nss|
			s|mozilla-nspr|nspr|" "${S}"/configure || die "sed 1 failed"
		G2CONF="${G2CONF} --enable-nss=yes"
	else
		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
			--without-nss-libs --without-nss-includes"
	fi

	# problems with -O3 on gcc-3.3.1
	replace-flags -O3 -O2
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "To change the default browser if you are not using GNOME, do:"
	elog "gconftool-2 --set /desktop/gnome/url-handlers/http/command -t string 'mozilla %s'"
	elog "gconftool-2 --set /desktop/gnome/url-handlers/https/command -t string 'mozilla %s'"
	elog ""
	elog "Replace 'mozilla %s' with which ever browser you use."
	elog ""
	elog "Junk filters are now a run-time choice. You will get a choice of"
	elog "bogofilter or spamassassin based on which you have installed"
	elog ""
	elog "You have to install one of these for the spam filtering to actually work"
}