[gentoo-commits] gentoo-x86 commit in dev-ml/camlimages: camlimages-4.2.1.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    15/06/28 14:13:22

  Modified:             ChangeLog
  Added:                camlimages-4.2.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.39                 dev-ml/camlimages/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlimages/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlimages/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlimages/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/camlimages/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	23 Oct 2014 10:57:44 -0000	1.38
+++ ChangeLog	28 Jun 2015 14:13:22 -0000	1.39
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/camlimages
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/ChangeLog,v 1.38 2014/10/23 10:57:44 aballier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/ChangeLog,v 1.39 2015/06/28 14:13:22 aballier Exp $
+
+*camlimages-4.2.1 (28 Jun 2015)
+
+  28 Jun 2015; Alexis Ballier <aballier@g.o> +camlimages-4.2.1.ebuild:
+  version bump
 
 *camlimages-4.1.2 (23 Oct 2014)
 



1.1                  dev-ml/camlimages/camlimages-4.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlimages/camlimages-4.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/camlimages/camlimages-4.2.1.ebuild?rev=1.1&content-type=text/plain

Index: camlimages-4.2.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/camlimages/camlimages-4.2.1.ebuild,v 1.1 2015/06/28 14:13:22 aballier Exp $

EAPI=5

inherit eutils vcs-snapshot findlib multilib

DESCRIPTION="An image manipulation library for ocaml"
HOMEPAGE="http://gallium.inria.fr/camlimages/"
SRC_URI="http://bitbucket.org/camlspotter/camlimages/get/${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc exif gif gtk jpeg png postscript tiff truetype X xpm"

RDEPEND=">=dev-lang/ocaml-3.10.2:=[X?,ocamlopt]
	exif? ( media-libs/libexif )
	gif? ( media-libs/giflib )
	gtk? ( dev-ml/lablgtk )
	jpeg? ( virtual/jpeg )
	tiff? ( media-libs/tiff )
	png? ( >=media-libs/libpng-1.4:0 )
	postscript? ( app-text/ghostscript-gpl )
	truetype? ( >=media-libs/freetype-2 )
	xpm? ( x11-libs/libXpm )
	X? ( x11-apps/rgb )
	sys-libs/zlib
	"
DEPEND="${DEPEND}
	doc? ( dev-python/sphinx[latex] )
	dev-util/omake
	virtual/pkgconfig
	dev-ml/findlib"

camlimages_arg_want() {
	echo "ARG_WANT_${2}=$(usex $1 1 0)"
}

src_compile() {
	omake \
		$(camlimages_arg_want exif        EXIF    ) \
		$(camlimages_arg_want gif         GIF     ) \
		$(camlimages_arg_want png         PNG     ) \
		$(camlimages_arg_want jpeg        JPEG    ) \
		$(camlimages_arg_want tiff        TIFF    ) \
		$(camlimages_arg_want xpm         XPM     ) \
		$(camlimages_arg_want postscript  GS      ) \
		$(camlimages_arg_want gtk         LABLGTK2) \
		$(camlimages_arg_want X           GRAPHICS) \
		$(camlimages_arg_want truetype    FREETYPE) \
		PATH_GS=/bin/true \
		--force-dotomake || die

	if use doc ; then
		sphinx-build doc/sphinx sphinxdoc || die
	fi
}

src_install() {
	findlib_src_preinst
	omake --force-dotomake DESTDIR="${D}" install || die
	dodoc README.rst
	use doc && dohtml -r sphinxdoc/*
}