[gentoo-commits] gentoo-x86 commit in media-libs/glew: glew-1.7.0.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    11/10/01 07:11:27

  Modified:             ChangeLog
  Added:                glew-1.7.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

Revision  Changes    Path
1.73                 media-libs/glew/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.73&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.73&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?r1=1.72&r2=1.73

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v
retrieving revision 1.72
retrieving revision 1.73
diff -u -r1.72 -r1.73
--- ChangeLog	1 Oct 2011 07:04:39 -0000	1.72
+++ ChangeLog	1 Oct 2011 07:11:27 -0000	1.73
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/glew
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.72 2011/10/01 07:04:39 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.73 2011/10/01 07:11:27 radhermit Exp $
+
+*glew-1.7.0 (01 Oct 2011)
+
+  01 Oct 2011; Tim Harder <radhermit@g.o> +glew-1.7.0.ebuild:
+  Version bump.
 
   01 Oct 2011; Tim Harder <radhermit@g.o> -glew-1.5.7-r1.ebuild,
   -glew-1.5.8.ebuild, -glew-1.6.0.ebuild:



1.1                  media-libs/glew/glew-1.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.7.0.ebuild?rev=1.1&content-type=text/plain

Index: glew-1.7.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/glew-1.7.0.ebuild,v 1.1 2011/10/01 07:11:27 radhermit Exp $

EAPI=4
inherit multilib toolchain-funcs

DESCRIPTION="The OpenGL Extension Wrangler Library"
HOMEPAGE="http://glew.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"

LICENSE="BSD MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc static-libs"

RDEPEND="x11-libs/libXmu
	x11-libs/libXi
	virtual/glu
	virtual/opengl
	x11-libs/libXext
	x11-libs/libX11"
DEPEND="${RDEPEND}"

pkg_setup() {
	myglewopts=(
		AR="$(tc-getAR)"
		STRIP=true
		CC="$(tc-getCC)"
		LD="$(tc-getCC) ${LDFLAGS}"
		M_ARCH=""
		LDFLAGS.EXTRA=""
		POPT="${CFLAGS}"
	)
}

src_prepare() {
	sed -i \
		-e '/INSTALL/s:-s::' \
		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
		Makefile || die

	if ! use static-libs ; then
		sed -i -e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
			-e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
			-e '/STRIP.* lib\/$(LIB.STATIC)/{N;d}' \
			-e '/STRIP.* lib\/$(LIB.STATIC.MX)/{N;d}' \
			Makefile || die
	fi

	# don't do stupid Solaris specific stuff that won't work in Prefix
	cp config/Makefile.linux config/Makefile.solaris || die
}

src_compile(){
	emake "${myglewopts[@]}"
}

src_install() {
	emake \
		GLEW_DEST="${ED}/usr" \
		LIBDIR="${ED}/usr/$(get_libdir)" \
		"${myglewopts[@]}" install.all

	dodoc TODO.txt
	use doc && dohtml doc/*
}