[gentoo-commits] repo/gentoo:master commit in: app-text/tree/

[Jonas Stein]

commit:     2670946f0c4bb8904286a9215cc40011ab758bac
Author:     Jonas Stein <jstein <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 20 20:14:55 2017 +0000
Commit:     Jonas Stein <jstein <AT> gentoo <DOT> org>
CommitDate: Mon Nov 20 20:36:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2670946f

app-text/tree: Bump to EAPI=6

EAPI bump and cleanup

Package-Manager: Portage-2.3.14, Repoman-2.3.5

 app-text/tree/tree-1.7.0-r1.ebuild | 42 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/app-text/tree/tree-1.7.0-r1.ebuild b/app-text/tree/tree-1.7.0-r1.ebuild
new file mode 100644
index 00000000000..25422873935
--- /dev/null
+++ b/app-text/tree/tree-1.7.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs flag-o-matic bash-completion-r1
+
+DESCRIPTION="Lists directories recursively, and produces an indented listing of files"
+HOMEPAGE="http://mama.indstate.edu/users/ice/tree/"
+SRC_URI="ftp://mama.indstate.edu/linux/tree/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+RDEPEND="!=sci-biology/meme-4.8.1"
+DEPEND=""
+
+src_prepare() {
+	sed -i -e 's:LINUX:__linux__:' tree.c || die
+	mv doc/tree.1.fr doc/tree.fr.1
+	if use !elibc_glibc ; then
+		# 433972, also previously done only for elibc_uclibc
+		sed -i -e '/^OBJS=/s/$/ strverscmp.o/' Makefile || die
+	fi
+	default
+}
+
+src_compile() {
+	append-lfs-flags
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin tree
+	doman doc/tree*.1
+	einstalldocs
+	newbashcomp "${FILESDIR}"/${PN}.bashcomp ${PN}
+}