[gentoo-commits] gentoo-x86 commit in dev-java/bcprov: bcprov-1.52.ebuild ChangeLog

[Patrice Clement (monsieurp)]

monsieurp    15/08/01 16:07:25

  Modified:             ChangeLog
  Added:                bcprov-1.52.ebuild
  Log:
  Version bump. Fixes bug 535882.
  
  Signed-off-by: Patrice Clement <monsieurp@g.o>
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 93491BB8)

Revision  Changes    Path
1.65                 dev-java/bcprov/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	19 May 2015 09:06:09 -0000	1.64
+++ ChangeLog	1 Aug 2015 16:07:25 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/bcprov
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v 1.64 2015/05/19 09:06:09 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v 1.65 2015/08/01 16:07:25 monsieurp Exp $
+
+*bcprov-1.52 (01 Aug 2015)
+
+  01 Aug 2015; Patrice Clement <monsieurp@g.o> +bcprov-1.52.ebuild:
+  Version bump. Fixes bug 535882.
 
   19 May 2015; Agostino Sarubbo <ago@g.o> bcprov-1.50.ebuild:
   Stable for x86, wrt bug #485564



1.1                  dev-java/bcprov/bcprov-1.52.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/bcprov-1.52.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/bcprov-1.52.ebuild?rev=1.1&content-type=text/plain

Index: bcprov-1.52.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/bcprov-1.52.ebuild,v 1.1 2015/08/01 16:07:25 monsieurp Exp $

EAPI="5"

JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

MY_P="${PN}-jdk15on-${PV/./}"
DESCRIPTION="Java cryptography APIs"
HOMEPAGE="http://www.bouncycastle.org/java.html"
SRC_URI="http://www.bouncycastle.org/download/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x64-macos"

# Tests are currently broken. Needs further investigation.
# java.security.NoSuchAlgorithmException: Cannot find any provider supporting McElieceFujisakiWithSHA256
RESTRICT="test"

# The src_unpack find needs a new find
# https://bugs.gentoo.org/show_bug.cgi?id=182276
DEPEND=">=virtual/jdk-1.6
	app-arch/unzip
	userland_GNU? (
		sys-apps/findutils
	)
	test? (
		dev-java/junit:4
	)"
RDEPEND=">=virtual/jre-1.6"

IUSE="userland_GNU"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	default
	cd "${S}" || die
	unpack ./src.zip
}

java_prepare() {
	mkdir "${S}"/classes || die

	if use test; then
		java-pkg_jar-from --build-only junit-4
	fi
}

src_compile() {
	find . -name "*.java" > "${T}"/src.list

	local cp
	if use test ; then
		cp="-cp junit.jar"
	else
		sed -i '/\/test\//d' "${T}"/src.list || die "Failed to remove test classes"
	fi

	ejavac $cp -encoding ISO-8859-1 -d "${S}"/classes "@${T}"/src.list

	cd "${S}"/classes || die

	jar -cf "${S}"/${PN}.jar * || die "Failed to create jar."
}

src_test() {
	java -cp ${PN}.jar:junit.jar org.bouncycastle.pqc.jcajce.provider.test.AllTests | tee pqc.tests
	java -cp ${PN}.jar:junit.jar org.bouncycastle.ocsp.test.AllTests | tee oscp.tests
	java -cp ${PN}.jar:junit.jar org.bouncycastle.jce.provider.test.AllTests | tee jce.tests

	grep -q FAILURES *.tests && die "Tests failed."
}

src_install() {
	java-pkg_dojar ${PN}.jar

	use source && java-pkg_dosrc org
	use doc && java-pkg_dojavadoc docs
}