[gentoo-commits] gentoo-x86 commit in media-libs/libao: libao-1.2.0.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    14/01/29 03:53:03

  Modified:             ChangeLog
  Added:                libao-1.2.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.117                media-libs/libao/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libao/ChangeLog?rev=1.117&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libao/ChangeLog?rev=1.117&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libao/ChangeLog?r1=1.116&r2=1.117

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libao/ChangeLog,v
retrieving revision 1.116
retrieving revision 1.117
diff -u -r1.116 -r1.117
--- ChangeLog	30 Nov 2013 17:11:39 -0000	1.116
+++ ChangeLog	29 Jan 2014 03:53:03 -0000	1.117
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libao
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libao/ChangeLog,v 1.116 2013/11/30 17:11:39 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libao/ChangeLog,v 1.117 2014/01/29 03:53:03 radhermit Exp $
+
+*libao-1.2.0 (29 Jan 2014)
+
+  29 Jan 2014; Tim Harder <radhermit@g.o> +libao-1.2.0.ebuild:
+  Version bump.
 
 *libao-1.1.0-r2 (30 Nov 2013)
 



1.1                  media-libs/libao/libao-1.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libao/libao-1.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libao/libao-1.2.0.ebuild?rev=1.1&content-type=text/plain

Index: libao-1.2.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libao/libao-1.2.0.ebuild,v 1.1 2014/01/29 03:53:03 radhermit Exp $

EAPI=5

inherit libtool multilib multilib-minimal eutils

DESCRIPTION="The Audio Output library"
HOMEPAGE="http://www.xiph.org/ao/"
SRC_URI="http://downloads.xiph.org/releases/ao/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="alsa nas mmap pulseaudio static-libs"

RDEPEND="alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
	nas? ( media-libs/nas[${MULTILIB_USEDEP}] )
	pulseaudio? ( media-sound/pulseaudio[${MULTILIB_USEDEP}] )
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20131008-r1
		!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	sed -i 's:-O20::' configure || die
	sed -i "s:/lib:/$(get_libdir):g" ao.m4 || die
	elibtoolize
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	econf \
		$(use_enable static-libs static) \
		--disable-esd \
		$(use_enable alsa alsa) \
		$(use_enable mmap alsa-mmap) \
		--disable-arts \
		$(use_enable nas) \
		$(use_enable pulseaudio pulse)
}

multilib_src_install() {
	emake DESTDIR="${D}" docdir="${EPREFIX}/usr/share/doc/${PF}/html" install
}

multilib_src_install_all() {
	dodoc AUTHORS CHANGES README TODO
	prune_libtool_files --all
}