[gentoo-commits] gentoo-x86 commit in app-admin/eselect: ChangeLog eselect-1.3.8.ebuild eselect-1.3.7.ebuild

[Ulrich Mueller (ulm)]

ulm         13/08/28 08:13:55

  Modified:             ChangeLog
  Added:                eselect-1.3.8.ebuild
  Removed:              eselect-1.3.7.ebuild
  Log:
  Version bump. Remove intermediate version.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.233                app-admin/eselect/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect/ChangeLog?rev=1.233&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect/ChangeLog?rev=1.233&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect/ChangeLog?r1=1.232&r2=1.233

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/eselect/ChangeLog,v
retrieving revision 1.232
retrieving revision 1.233
diff -u -r1.232 -r1.233
--- ChangeLog	25 Aug 2013 13:05:03 -0000	1.232
+++ ChangeLog	28 Aug 2013 08:13:55 -0000	1.233
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/eselect
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/ChangeLog,v 1.232 2013/08/25 13:05:03 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/ChangeLog,v 1.233 2013/08/28 08:13:55 ulm Exp $
+
+*eselect-1.3.8 (28 Aug 2013)
+
+  28 Aug 2013; Ulrich Müller <ulm@g.o> -eselect-1.3.7.ebuild,
+  +eselect-1.3.8.ebuild:
+  Version bump. Remove intermediate version.
 
   25 Aug 2013; Jeroen Roovers <jer@g.o> eselect-1.3.7.ebuild:
   Stable for HPPA (bug #482308).



1.1                  app-admin/eselect/eselect-1.3.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect/eselect-1.3.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect/eselect-1.3.8.ebuild?rev=1.1&content-type=text/plain

Index: eselect-1.3.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/eselect-1.3.8.ebuild,v 1.1 2013/08/28 08:13:55 ulm Exp $

EAPI=4

inherit eutils bash-completion-r1

DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
HOMEPAGE="http://wiki.gentoo.org/wiki/Project:Eselect"
SRC_URI="mirror://gentoo/${P}.tar.xz"

LICENSE="GPL-2+ || ( GPL-2+ CC-BY-SA-2.5 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="doc emacs vim-syntax"

RDEPEND="sys-apps/sed
	|| (
		sys-apps/coreutils
		sys-freebsd/freebsd-bin
		app-misc/realpath
	)"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	doc? ( dev-python/docutils )"
RDEPEND="!app-admin/eselect-news
	${RDEPEND}
	sys-apps/file
	sys-libs/ncurses"

PDEPEND="emacs? ( app-emacs/eselect-mode )
	vim-syntax? ( app-vim/eselect-syntax )"

src_compile() {
	emake
	use doc && emake html
}

src_install() {
	emake DESTDIR="${D}" install
	newbashcomp misc/${PN}.bashcomp ${PN}
	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
	use doc && dohtml *.html doc/*

	# needed by news module
	keepdir /var/lib/gentoo/news
	if ! use prefix; then
		fowners root:portage /var/lib/gentoo/news
		fperms g+w /var/lib/gentoo/news
	fi
}

pkg_postinst() {
	# fowners in src_install doesn't work for the portage group:
	# merging changes the group back to root
	if ! use prefix; then
		chgrp portage "${EROOT}/var/lib/gentoo/news" \
			&& chmod g+w "${EROOT}/var/lib/gentoo/news"
	fi
}