[gentoo-commits] repo/gentoo:master commit in: dev-util/vulkan-tools/

[Nick Sarnie]

commit:     fc0c7ffef2e01b2599211b144d8fba270e1cad97
Author:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Thu May 27 02:13:36 2021 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Thu May 27 02:32:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fc0c7ffe

dev-util/vulkan-tools: Version bump

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 dev-util/vulkan-tools/Manifest                    |  1 +
 dev-util/vulkan-tools/vulkan-tools-1.2.179.ebuild | 81 +++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/dev-util/vulkan-tools/Manifest b/dev-util/vulkan-tools/Manifest
index 2d47c28db34..557b3b89dc9 100644
--- a/dev-util/vulkan-tools/Manifest
+++ b/dev-util/vulkan-tools/Manifest
@@ -1,2 +1,3 @@
 DIST vulkan-tools-1.2.162.tar.gz 724232 BLAKE2B 16eb2dde35883fb2c7c263a72a615818ff8e1557ac9d74553ec3784d96a827e6900efa4e42218cb9081f7501d9b1a53eac82c360c2d20922043308515ab48983 SHA512 7827f6775dfb26820a2a2cbc60e7da8c7e7bdcb57b65523fbc6b2e989ae6869b04a57ae458c72715722c67d842660574697834c92f9b909dd5673da1945ac6dc
 DIST vulkan-tools-1.2.170.tar.gz 835063 BLAKE2B 5b7b9c9ea07b3a25d2b989a0981417b4a1c4f97d03fc9f1ab765ac2ade3bd33e99657813a3cb6b3290559539cd9dca3d6992cacf848c0ea9eee536eeef99553f SHA512 0cc361c1a7cecf74dab25e6a4bead7870a0cf363b07a6e5fbd6fa245027fb8e4f2b651affda095fadad90e114507c4f80370c2fcb4e6b9cbc013eac8a67d2d6b
+DIST vulkan-tools-1.2.179.tar.gz 843725 BLAKE2B 0304f7672b5405404dca9b9800dd0927f3af0f17580f021bc30e651ecda5b5e6194971a6a95e30cce956d094cc8fbab580f0f0ecd8fa4c81a9bc15ced5ad92ac SHA512 227b5023c21720c94fb5583f0f6635cf2b9d8067cae02dc6f22f39a106bc0b3e569b2730a1dc4fd469fe0a5e5653167fdc56fe37852a1acfc38df953b4524dcc

diff --git a/dev-util/vulkan-tools/vulkan-tools-1.2.179.ebuild b/dev-util/vulkan-tools/vulkan-tools-1.2.179.ebuild
new file mode 100644
index 00000000000..12745cbcc1b
--- /dev/null
+++ b/dev-util/vulkan-tools/vulkan-tools-1.2.179.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Tools
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{7,8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland +X"
+
+# Cube demo only supports one window system at a time
+REQUIRED_USE="!cube? ( || ( X wayland ) ) cube? ( ^^ ( X wayland ) )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-util/cmake-3.10.2
+	cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	>=media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-util/vulkan-headers-${PV}
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${EPREFIX}/usr"
+	)
+
+	use cube && mycmakeargs+=(
+		-DGLSLANG_INSTALL_DIR="${EPREFIX}/usr"
+		-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+}