[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: ChangeLog redshift-1.9.1.ebuild

[Sebastian Pipping (sping)]

sping       14/07/26 21:01:27

  Modified:             ChangeLog
  Added:                redshift-1.9.1.ebuild
  Log:
  x11-misc/redshift: 1.9.1 (bug #518058)
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

Revision  Changes    Path
1.24                 x11-misc/redshift/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	13 Apr 2014 17:51:26 -0000	1.23
+++ ChangeLog	26 Jul 2014 21:01:26 -0000	1.24
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/redshift
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.23 2014/04/13 17:51:26 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.24 2014/07/26 21:01:26 sping Exp $
+
+*redshift-1.9.1 (26 Jul 2014)
+
+  26 Jul 2014; Sebastian Pipping <sping@g.o> +redshift-1.9.1.ebuild:
+  Bump to 1.9.1 (bug #518058)
 
 *redshift-1.9-r1 (13 Apr 2014)
 



1.1                  x11-misc/redshift/redshift-1.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.9.1.ebuild?rev=1.1&content-type=text/plain

Index: redshift-1.9.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/redshift-1.9.1.ebuild,v 1.1 2014/07/26 21:01:26 sping Exp $

EAPI=5
PYTHON_COMPAT=( python{3_2,3_3} )

inherit autotools eutils gnome2-utils python-r1

DESCRIPTION="A screen color temperature adjusting software"
HOMEPAGE="http://jonls.dk/redshift/"
SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="geoclue gtk nls"

COMMON_DEPEND=">=x11-libs/libX11-1.4
	x11-libs/libXxf86vm
	x11-libs/libxcb
	x11-libs/libdrm
	geoclue? ( app-misc/geoclue:0 dev-libs/glib:2 )
	gtk? ( ${PYTHON_DEPS} )"
RDEPEND="${COMMON_DEPEND}
	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
		dev-python/pyxdg[${PYTHON_USEDEP}] )"
DEPEND="${COMMON_DEPEND}
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch_user
	eautoreconf
}

src_configure() {
	python_export_best

	econf \
		--disable-silent-rules \
		$(use_enable nls) \
		--enable-drm \
		--enable-randr \
		--enable-vidmode \
		--disable-wingdi \
		$(use_enable geoclue) \
		$(use_enable gtk gui) \
		--disable-ubuntu
}

_impl_specific_src_install() {
	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
			-C src/redshift-gtk install
}

src_install() {
	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install

	if use gtk; then
		python_foreach_impl _impl_specific_src_install
		python_replicate_script "${D}"/usr/bin/redshift-gtk
		dosym redshift-gtk /usr/bin/gtk-redshift
	fi
}

pkg_preinst() {
	use gtk && gnome2_icon_savelist
}

pkg_postinst() {
	use gtk && gnome2_icon_cache_update
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
}