[gentoo-commits] gentoo-x86 commit in dev-lang/qu-prolog: ChangeLog qu-prolog-9.1.ebuild

[Keri Harris (keri)]

keri        11/11/19 18:20:30

  Modified:             ChangeLog
  Added:                qu-prolog-9.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 dev-lang/qu-prolog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/qu-prolog/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	18 Nov 2011 21:00:02 -0000	1.82
+++ ChangeLog	19 Nov 2011 18:20:30 -0000	1.83
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/qu-prolog
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.82 2011/11/18 21:00:02 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.83 2011/11/19 18:20:30 keri Exp $
+
+*qu-prolog-9.1 (19 Nov 2011)
+
+  19 Nov 2011; <keri@g.o> +qu-prolog-9.1.ebuild,
+  +files/qu-prolog-9.1-cerr-ptr.patch, +files/qu-prolog-9.1-cflags.patch,
+  +files/qu-prolog-9.1-portage.patch:
+  Version bump
 
 *qu-prolog-9.0 (18 Nov 2011)
 



1.1                  dev-lang/qu-prolog/qu-prolog-9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/qu-prolog/qu-prolog-9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/qu-prolog/qu-prolog-9.1.ebuild?rev=1.1&content-type=text/plain

Index: qu-prolog-9.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/qu-prolog-9.1.ebuild,v 1.1 2011/11/19 18:20:30 keri Exp $

EAPI=2

inherit eutils qt4-r2

MY_P=qp${PV}

DESCRIPTION="Qu-Prolog is an extended Prolog supporting quantifiers, object-variables and substitutions"
HOMEPAGE="http://www.itee.uq.edu.au/~pjr/HomePages/QuPrologHome.html"
SRC_URI="http://www.itee.uq.edu.au/~pjr/HomePages/QPFiles/${MY_P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug doc examples pedro qt4 readline threads"

RDEPEND="!dev-util/mpatch
	!dev-util/rej
	qt4? ( x11-libs/qt-gui:4 )
	pedro? ( net-misc/pedro )
	readline? ( app-misc/rlwrap )"

DEPEND="${RDEPEND}
	dev-lang/perl"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-portage.patch
	epatch "${FILESDIR}"/${P}-cflags.patch
	epatch "${FILESDIR}"/${P}-cerr-ptr.patch
}

src_configure() {
	econf \
		--libdir=/usr/$(get_libdir) \
		$(use_enable debug) \
		$(use_enable threads multiple-threads)

	if use qt4; then
		cd "${S}"/src/xqp
		eqmake4 xqp.pro
	fi
}

src_compile() {
	emake || die "emake failed"

	if use qt4; then
		cd "${S}"/src/xqp
		emake || die "emake xqp failed"
	fi
}

src_install() {
	sed -i -e "s|${S}|/usr/$(get_libdir)/qu-prolog|g" \
		bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp || die

	exeinto /usr/bin
	doexe bin/qa bin/qdeal bin/qem bin/ql || die
	doexe bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp bin/qppp || die
	doexe bin/kq || die

	if use qt4; then
		doexe src/xqp/xqp || die
	fi

	insinto /usr/$(get_libdir)/${PN}/bin
	doins bin/rl_commands
	doins bin/qc1.qup.qx \
		bin/qecat.qx \
		bin/qg.qx \
		bin/qp.qx || die

	insinto /usr/$(get_libdir)/${PN}/library
	doins prolog/library/*.qo || die

	insinto /usr/$(get_libdir)/${PN}/compiler
	doins prolog/compiler/*.qo || die

	doman doc/man/man1/*.1 || die

	dodoc README || die

	if use doc ; then
		docinto reference-manual
		dodoc doc/manual/*.html || die
		docinto user-guide
		dodoc doc/user/main.pdf || die
	fi

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.ql || die
		docinto examples
		dodoc examples/README || die
	fi
}