[gentoo-commits] gentoo-x86 commit in sci-chemistry/pymol: pymol-1.0-r1.ebuild pymol-1.2.1.ebuild ChangeLog pymol-0.99_rc10.ebuild

[Jeffrey Gardner (je_fro)]

je_fro      09/08/02 14:58:31

  Modified:             pymol-1.0-r1.ebuild ChangeLog
                        pymol-0.99_rc10.ebuild
  Added:                pymol-1.2.1.ebuild
  Log:
  New version, works with python 2.6, closes bug #269119. Many thanks to Justin Lecher for doing the work, and fauli for a kick in the pants :)
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sci-chemistry/pymol/pymol-1.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild?r1=1.3&r2=1.4

Index: pymol-1.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- pymol-1.0-r1.ebuild	17 Aug 2008 03:06:59 -0000	1.3
+++ pymol-1.0-r1.ebuild	2 Aug 2009 14:58:31 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild,v 1.3 2008/08/17 03:06:59 je_fro Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.0-r1.ebuild,v 1.4 2009/08/02 14:58:31 je_fro Exp $
 
 inherit distutils eutils multilib subversion
 
@@ -22,6 +22,8 @@
 sys-libs/zlib
 virtual/glut"
 
+RDEPEND="${DEPEND}"
+
 src_unpack() {
 	subversion_src_unpack
 



1.43                 sci-chemistry/pymol/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	6 May 2009 21:06:39 -0000	1.42
+++ ChangeLog	2 Aug 2009 14:58:31 -0000	1.43
@@ -1,6 +1,14 @@
 # ChangeLog for sci-chemistry/pymol
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.42 2009/05/06 21:06:39 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.43 2009/08/02 14:58:31 je_fro Exp $
+
+*pymol-1.2.1 (02 Aug 2009)
+
+  02 Aug 2009; Jeff Gardner <je_fro@g.o> +pymol-1.2.1.ebuild,
+  +files/1.2.1/pymol-1.2.1-data-path.patch,
+  +files/1.2.1/pymol-1.2.1-shaders.patch:
+  New version, works with python 2.6, closes bug #269119. Many thanks to
+  Justin Lecher for doing the work, and fauli for a kick in the pants :)
 
   06 May 2009; Markus Meier <maekke@g.o> pymol-1.1-r2.ebuild:
   amd64/x86 stable, bug #250903



1.9                  sci-chemistry/pymol/pymol-0.99_rc10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild?r1=1.8&r2=1.9

Index: pymol-0.99_rc10.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- pymol-0.99_rc10.ebuild	16 Apr 2009 13:42:53 -0000	1.8
+++ pymol-0.99_rc10.ebuild	2 Aug 2009 14:58:31 -0000	1.9
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild,v 1.8 2009/04/16 13:42:53 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-0.99_rc10.ebuild,v 1.9 2009/08/02 14:58:31 je_fro Exp $
 
 inherit distutils eutils multilib subversion
 
@@ -20,6 +20,8 @@
 sys-libs/zlib
 virtual/glut"
 
+RDEPEND="${DEPEND}"
+
 src_unpack() {
 	subversion_src_unpack
 



1.1                  sci-chemistry/pymol/pymol-1.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild?rev=1.1&content-type=text/plain

Index: pymol-1.2.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild,v 1.1 2009/08/02 14:58:31 je_fro Exp $

EAPI="2"

inherit distutils subversion

PYTHON_MODNAME="chempy pmg_tk pymol"
APBS_PATCH="090618"
REV="3825"

DESCRIPTION="A Python-extensible molecular graphics system."
HOMEPAGE="http://pymol.sourceforge.net/"
SRC_URI="apbs? ( mirror://gentoo/apbs_tools.py.${APBS_PATCH}.bz2 )"
ESVN_REPO_URI="https://pymol.svn.sourceforge.net/svnroot/pymol/trunk/pymol@${REV}"

LICENSE="PSF-2.2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="apbs shaders"

DEPEND="dev-python/pmw
		dev-python/numpy
		>=dev-lang/python-2.4[tk]
		media-libs/libpng
		sys-libs/zlib
		virtual/glut
		media-video/mpeg-tools
		apbs? ( dev-libs/maloc
			sci-chemistry/apbs
			sci-chemistry/pdb2pqr
		)"
RDEPEND="${DEPEND}"

pkg_setup(){
	python_version
}

src_unpack() {
	use apbs && unpack ${A}
	subversion_src_unpack
}

src_prepare() {
	epatch "${FILESDIR}"/${PV}/${P}-data-path.patch \
		|| die "Failed to apply data-path.patch"

	# Turn off splash screen.  Please do make a project contribution
	# if you are able though.
	[[ -n ${WANT_SPLASH} ]] || epatch "${FILESDIR}"/nosplash-gentoo.patch

	# Respect CFLAGS
	sed -i \
		-e "s:\(ext_comp_args=\).*:\1[]:g" \
		"${S}"/setup.py || die "Failed running sed on setup.py"

	use shaders && epatch "${FILESDIR}"/${PV}/${P}-shaders.patch

	if use apbs; then
		cp -f "${WORKDIR}"/apbs_tools.py.${APBS_PATCH} modules/pmg_tk/startup/apbs_tools.py \
			|| die "Failed to copy apbs_tools.py"

		sed "s:LIBANDPYTHON:$(python_get_libdir):g" \
			-i modules/pmg_tk/startup/apbs_tools.py \
				|| die "Failed running sed on apbs_tools.py"
	fi
}

src_configure() {
	:
}

src_install() {
	distutils_src_install

	# These environment variables should not go in the wrapper script, or else
	# it will be impossible to use the PyMOL libraries from Python.
	cat >> "${T}"/20pymol <<- EOF
		PYMOL_PATH=$(python_get_sitedir)/${PN}
		PYMOL_DATA="/usr/share/pymol/data"
		PYMOL_SCRIPTS="/usr/share/pymol/scripts"
	EOF

	if use apbs; then
		echo "APBS_PSIZE=$(python_get_sitedir)/pdb2pqr/src/psize.py" >> "${T}"/20pymol
	fi

	doenvd "${T}"/20pymol || die "Failed to install env.d file."

	cat >> "${T}"/pymol <<- EOF
	#!/bin/sh
	${python} -O \${PYMOL_PATH}/__init__.py \$*
	EOF

	dobin "${T}"/pymol || die "Failed to install wrapper."

	insinto /usr/share/pymol
	doins -r test data scripts || die "no shared data"

	insinto /usr/share/pymol/examples
	doins -r examples || die "Failed to install docs."

	dodoc DEVELOPERS README || die "Failed to install docs."

	if ! use apbs; then
		rm "${D}"$(python_get_sitedir)/pmg_tk/startup/apbs_tools.py
	fi
}

pkg_postinst(){
	distutils_pkg_postinst

	# The apbs ebuild was just corrected and not bumped #213616
	if use apbs; then
		[ -e /usr/share/apbs-0.5* ] && \
		ewarn "You need to reemerge sci-chemistry/apbs!"
	fi
}