[gentoo-commits] gentoo-x86 commit in media-sound/mumble: ChangeLog mumble-1.1.1.ebuild

[Timothy Redaelli (drizzt)]

drizzt      07/12/23 20:19:11

  Modified:             ChangeLog
  Added:                mumble-1.1.1.ebuild
  Log:
  Add new media-sound/mumble for testing wrt bug #183781.
  
  (Portage version: 2.1.4_rc10)

Revision  Changes    Path
1.8                  media-sound/mumble/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	5 May 2007 19:13:10 -0000	1.7
+++ ChangeLog	23 Dec 2007 20:19:11 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mumble
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v 1.7 2007/05/05 19:13:10 drizzt Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/ChangeLog,v 1.8 2007/12/23 20:19:11 drizzt Exp $
+
+*mumble-1.1.1 (23 Dec 2007)
+
+  23 Dec 2007; Timothy Redaelli <drizzt@g.o>
+  +files/mumble-1.1.1-path.patch, +mumble-1.1.1.ebuild:
+  Add new media-sound/mumble for testing wrt bug #183781.
 
   05 May 2007; Timothy Redaelli <drizzt@g.o>
   files/mumble-0.9.4-path.patch, mumble-0.9.4.ebuild:



1.1                  media-sound/mumble/mumble-1.1.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/mumble-1.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mumble/mumble-1.1.1.ebuild?rev=1.1&content-type=text/plain

Index: mumble-1.1.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mumble/mumble-1.1.1.ebuild,v 1.1 2007/12/23 20:19:11 drizzt Exp $

inherit eutils toolchain-funcs qt4

DESCRIPTION="Voice chat software for gaming written in Qt4"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pulseaudio vanilla"

DEPEND="$(qt4_min_version 4.3)
	>=media-libs/speex-1.2_beta2
	media-libs/alsa-lib
	dev-libs/boost
	x11-libs/libXevie
	pulseaudio? ( media-sound/pulseaudio )"

RDEPEND="${DEPEND}"

pkg_setup() {
	if ! built_with_use -a =x11-libs/qt-4* sqlite3 dbus ; then
		echo
		if ! built_with_use =x11-libs/qt-4* sqlite3; then
			eerror "You need to build Qt4 with the sqlite3 use-flag"
		fi
		if ! built_with_use =x11-libs/qt-4* dbus; then
			eerror "You need to build Qt4 with the dbus use-flag"
		fi
		echo
		die "Your Qt4 installation lacks propper useflag configuration, see above"
	fi

	if [[ $(gcc-major-version) -eq 3 && $(gcc-minor-version) -lt 4 ]]; then
		eerror "You need >=sys-devel/gcc-3.4 to compile ${PN}."
		die "System gcc is too old to compile ${PN}."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	use pulseaudio || sed -i -e '/CONFIG  += oss/s/ pulseaudio//' \
		"${S}"/src/mumble/mumble.pro || die
	use vanilla || epatch "${FILESDIR}"/${P}-path.patch
}

src_compile() {
	local dir
	for dir in src/mumble overlay_gl; do
		cd "${S}/$dir"
		qmake ${dir##*/}.pro	|| die "qmake failed"
		lrelease ${dir##*/}.pro || die "lrelease failed"
		emake CC="$(tc-getCC) ${CFLAGS}" \
			CXX="$(tc-getCXX) ${CXXFLAGS}" \
			LINK="$(tc-getCXX)" || die "emake failed"
	done
}

src_install() {
	newdoc README.Linux README
	dodoc CHANGES

	local dir
	if built_with_use =x11-libs/qt-4* debug; then
		dir=debug
		ewarn "Built debug-version because your Qt4 has the debug use-flag enabled."
	else
		dir=release
	fi

	dobin ${dir}/mumble	|| die "installing failed"
	dolib.so ${dir}/lib*.so* || die "installing failed"
	
	dobin scripts/mumble-overlay || die "installing failed"
	newicon icons/mumble.64x64.png mumble.png || die "installing icon failed"
	make_desktop_entry ${PN} "Mumble" mumble.png "KDE;Qt;AudioVideo" \
		|| die "installing menu entry failed"
}

pkg_postinst() {
	elog
	elog "Visit http://mumble.sourceforge.net/Audio_Tuning for futher configuration"
	elog "type mumble to run the client"
	elog "you might want to add this to your xorg.conf to get shortcut support"
	elog "  Section \"Extensions\""
	elog "   Option         \"XEVIE\" \"Enable\""
	elog "  EndSection"
}



-- 
gentoo-commits@g.o mailing list