[gentoo-commits] repo/gentoo:master commit in: dev-python/graph-tool/

[Patrick Lauer]

commit:     849fde5d64f865cfd1a308b7f5ea8ad21a4ae764
Author:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 30 06:07:32 2017 +0000
Commit:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
CommitDate: Sat Sep 30 06:07:59 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=849fde5d

dev-python/graph-tool: Bump

Package-Manager: Portage-2.3.10, Repoman-2.3.3

 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.23.ebuild | 82 ++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 4286e501116..2eaac0310aa 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1,2 +1,3 @@
 DIST graph-tool-2.19.tar.bz2 15147961 SHA256 eba1090f94b0434890beedaf0c100dd0fc77e41ebfe29b4725d76cadb82099af SHA512 dc0bd93ccf21bb6616035dbfe33b0d9406eb894791e615795d486dc8f9d9991a6b93cf835cf4e59197005c14faedf105f3384cccd42db544104840cf857b2a84 WHIRLPOOL 3a398c98487a1e29952fea4c3ff8671e5aaf3d4f9e8df26aae9f6a856e61c290954f4c662e48ae424cbe0b916833a8f3bc7a6eefe6c6c3a08540de58ed6b9de0
 DIST graph-tool-2.22.tar.bz2 15100673 SHA256 57121b562763c79c138b3a385b8cddb59e7dec375c61e00ca7e9e96fd1a5e080 SHA512 e5ffb6913ba76c1b3dea597950b8d50edd55cb997bf8b02c105ffab314b4978ac861db0c57507e51598f731b6b8fa9f1251e21d5feb9eb89158bc4c1921dc51f WHIRLPOOL d4f2cf19ef885ad22837ba693e65ebe5f2fc379bcafe2d23eb42327d1aad49fb2a73b4b0eb24eb4cde3d6a77b9b6dc2c05dfd01aec83d53d5c3ebbdf1be82aae
+DIST graph-tool-2.23.tar.bz2 14998733 SHA256 5278f7d7504c7d4de2b259a079f37c894d4ee11daa53ba6f5d646a13e4a4da34 SHA512 bd7e493806152d004ed8fcd5cd93f8a27200b0acacde07026ad6f83e8b9a0cdbdedfee79f5ff4c41de179ea3293a1d100571501e8791dad2ff608ecb424a9e36 WHIRLPOOL 0a623944245f190d9b535c0d514ba0023c006c91bb2affbf4038d23ffdf852cf5ba954a8b3ff5743cb97842f78007ae78063f95babe12814126dbfcffc24c846

diff --git a/dev-python/graph-tool/graph-tool-2.23.ebuild b/dev-python/graph-tool/graph-tool-2.23.ebuild
new file mode 100644
index 00000000000..cf9f4302985
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.23.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	>=sci-mathematics/cgal-4.9
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash
+	virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	local threads
+	has_version 'dev-libs/boost[threads]' && threads="-mt"
+
+	configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="${EPYTHON: -3}${threads}"
+	}
+	python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+	# most machines don't have enough ram for parallel builds
+	python_foreach_impl run_in_build_dir emake -j1
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name '*.la' -delete || die
+}