[gentoo-commits] gentoo-x86 commit in net-analyzer/hping: ChangeLog hping-3_pre20051105-r3.ebuild hping-3_pre20051105-r1.ebuild hping-3_pre20051105-r2.ebuild

[Jeroen Roovers (jer)]

jer         10/11/30 21:30:45

  Modified:             ChangeLog
  Added:                hping-3_pre20051105-r3.ebuild
  Removed:              hping-3_pre20051105-r1.ebuild
                        hping-3_pre20051105-r2.ebuild
  Log:
  Fix overflow in scan.c (bug #340251). Simplify src_configure and export CC there. Set RDEPEND.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux i686)

Revision  Changes    Path
1.50                 net-analyzer/hping/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	11 May 2010 04:08:17 -0000	1.49
+++ ChangeLog	30 Nov 2010 21:30:45 -0000	1.50
@@ -1,6 +1,14 @@
 # ChangeLog for net-analyzer/hping
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v 1.49 2010/05/11 04:08:17 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/ChangeLog,v 1.50 2010/11/30 21:30:45 jer Exp $
+
+*hping-3_pre20051105-r3 (30 Nov 2010)
+
+  30 Nov 2010; Jeroen Roovers <jer@g.o> -hping-3_pre20051105-r1.ebuild,
+  -hping-3_pre20051105-r2.ebuild, +hping-3_pre20051105-r3.ebuild,
+  +files/hping-3_pre20051105-scan-overflow.patch:
+  Fix overflow in scan.c (bug #340251). Simplify src_configure and export CC
+  there. Set RDEPEND.
 
 *hping-3_pre20051105-r2 (11 May 2010)
 



1.1                  net-analyzer/hping/hping-3_pre20051105-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r3.ebuild?rev=1.1&content-type=text/plain

Index: hping-3_pre20051105-r3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/hping/hping-3_pre20051105-r3.ebuild,v 1.1 2010/11/30 21:30:45 jer Exp $

EAPI="2"

inherit eutils multilib toolchain-funcs

MY_P="${PN}${PV//_pre/-}"
DESCRIPTION="A ping-like TCP/IP packet assembler/analyzer"
HOMEPAGE="http://www.hping.org"
SRC_URI="http://www.hping.org/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86"
IUSE="tcl"

S="${WORKDIR}/${MY_P}"

DEPEND="net-libs/libpcap
	tcl? ( dev-lang/tcl )"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}.patch \
		"${FILESDIR}"/bytesex.h.patch \
		"${FILESDIR}"/${P}-tcl.patch \
		"${FILESDIR}"/${P}-ldflags.patch \
		"${FILESDIR}"/${P}-libtcl.patch \
		"${FILESDIR}"/${P}-scan-overflow.patch

	# Correct hard coded values
	sed -i Makefile.in \
		-e '/^CC=/d' \
		-e '/^AR=/d' \
		-e '/^RANLIB=/d' \
		-e 's:/usr/local/lib:/usr/$(LIBDIR):g' \
		-e 's:-O2:$(CFLAGS):' \
		|| die "sed Makefile.in failed"

	# Change name from hping2 to hping3
	sed -i docs/hping3.8 \
		-e 's|HPING2|HPING|g' \
		-e 's|hping2|hping|g' \
		|| die "sed hping3.8 failed"
}

src_configure() {
	tc-export CC

	# Not an autotools type configure:
	sh configure $(use tcl || echo --no-tcl) || die "configure failed"
}

src_compile() {
	emake \
		DEBUG="" \
		"CFLAGS=${CFLAGS}" \
		"AR=$(tc-getAR)" \
		"RANLIB=$(tc-getRANLIB)" \
		"LIBDIR=$(get_libdir)" \
		|| die "emake failed"
}

src_install () {
	dosbin hping3
	dosym /usr/sbin/hping3 /usr/sbin/hping
	dosym /usr/sbin/hping3 /usr/sbin/hping2

	newman docs/hping3.8 hping.8

	dodoc INSTALL NEWS README TODO AUTHORS BUGS CHANGES
}