[gentoo-commits] gentoo-x86 commit in games-engines/solarus: solarus-1.3.0.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/08/24 15:44:26

  Modified:             ChangeLog
  Added:                solarus-1.3.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.4                  games-engines/solarus/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/solarus/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/solarus/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/solarus/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-engines/solarus/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	7 Aug 2014 21:01:19 -0000	1.3
+++ ChangeLog	24 Aug 2014 15:44:26 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for games-engines/solarus
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/solarus/ChangeLog,v 1.3 2014/08/07 21:01:19 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-engines/solarus/ChangeLog,v 1.4 2014/08/24 15:44:26 hasufell Exp $
+
+*solarus-1.3.0 (24 Aug 2014)
+
+  24 Aug 2014; Julian Ospald <hasufell@g.o> +solarus-1.3.0.ebuild:
+  version bump
 
 *solarus-1.2.1 (07 Aug 2014)
 



1.1                  games-engines/solarus/solarus-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/solarus/solarus-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-engines/solarus/solarus-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: solarus-1.3.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-engines/solarus/solarus-1.3.0.ebuild,v 1.1 2014/08/24 15:44:26 hasufell Exp $

EAPI=5

inherit cmake-utils games

DESCRIPTION="An open-source Zelda-like 2D game engine"
HOMEPAGE="http://www.solarus-games.org/"
SRC_URI="http://www.zelda-solarus.com/downloads/${PN}/${P}-src.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc luajit"

RDEPEND="
	dev-games/physfs
	media-libs/libmodplug
	>=media-libs/libsdl2-2.0.1[X,joystick,video]
	media-libs/libvorbis
	media-libs/openal
	media-libs/sdl2-image[png]
	>=media-libs/sdl2-ttf-2.0.12
	luajit? ( dev-lang/luajit:2 )
	!luajit? ( dev-lang/lua )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

src_prepare() {
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DSOLARUS_INSTALL_DESTINATION="${GAMES_BINDIR}"
		$(cmake-utils_use luajit SOLARUS_USE_LUAJIT)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc ; then
		cd doc || die
		doxygen || die
	fi
}

src_install() {
	cmake-utils_src_install
	doman solarus.6
	use doc && dohtml -r doc/${PV%.*}/html/*
	prepgamesdirs
}