[gentoo-commits] gentoo-x86 commit in app-emulation/ganeti: ChangeLog ganeti-2.1.5.ebuild

[Lance Albertson (ramereth)]

ramereth    10/07/02 22:56:07

  Modified:             ChangeLog
  Added:                ganeti-2.1.5.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.24                 app-emulation/ganeti/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	20 Jun 2010 20:47:55 -0000	1.23
+++ ChangeLog	2 Jul 2010 22:56:07 -0000	1.24
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/ganeti
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.23 2010/06/20 20:47:55 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.24 2010/07/02 22:56:07 ramereth Exp $
+
+*ganeti-2.1.5 (02 Jul 2010)
+
+  02 Jul 2010; Lance Albertson <ramereth@g.o> +ganeti-2.1.5.ebuild:
+  Version bump
 
 *ganeti-2.2.0_beta0 (20 Jun 2010)
 *ganeti-2.1.4 (20 Jun 2010)



1.1                  app-emulation/ganeti/ganeti-2.1.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ganeti-2.1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ganeti-2.1.5.ebuild?rev=1.1&content-type=text/plain

Index: ganeti-2.1.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ganeti-2.1.5.ebuild,v 1.1 2010/07/02 22:56:07 ramereth Exp $

EAPI=2

inherit eutils confutils bash-completion

MY_PV="${PV/_rc/~rc}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Ganeti is a virtual server management software tool"
HOMEPAGE="http://code.google.com/p/ganeti/"
SRC_URI="http://ganeti.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="kvm xen drbd +filestorage syslog"

S="${WORKDIR}/${MY_P}"

DEPEND="xen? ( >=app-emulation/xen-3.0 )
	kvm? ( app-emulation/qemu-kvm )
	drbd? ( >=sys-cluster/drbd-8.0 )
	dev-libs/openssl
	dev-python/pyopenssl
	dev-python/pyparsing
	dev-python/pyinotify
	dev-python/simplejson
	net-analyzer/arping
	net-misc/bridge-utils
	net-misc/openssh
	net-misc/socat
	sys-apps/iproute2
	sys-fs/lvm2"
RDEPEND="${DEPEND}"

pkg_setup () {
	confutils_require_any kvm xen
}

src_configure () {
	local myconf
	if use filestorage ; then
		myconf="--with-file-storage-dir=/var/lib/ganeti-storage/file"
	else
		myconf="--with-file-storage-dir=no"
	fi
	econf --localstatedir=/var \
		--docdir=/usr/share/doc/${P} \
		--with-ssh-initscript=/etc/init.d/sshd \
		--with-export-dir=/var/lib/ganeti-storage/export \
		--with-os-search-path=/usr/share/ganeti/os \
		$(use_enable syslog) \
		${myconf}
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"
	newinitd "${FILESDIR}"/ganeti-2.1.initd ganeti
	newconfd "${FILESDIR}"/ganeti.confd ganeti
	dobashcompletion doc/examples/bash_completion ganeti
	dodoc INSTALL NEWS README doc/*.rst
	rm -rf "${D}"/usr/share/doc/ganeti
	docinto examples
	dodoc doc/examples/{dumb-allocator,ganeti.cron,gnt-config-backup}
	docinto examples/hooks
	dodoc doc/examples/hooks/{ipsec,ethers}

	keepdir /var/{lib,log,run}/ganeti/
	keepdir /usr/share/ganeti/os/
	keepdir /var/lib/ganeti-storage/{export,file}/
}

pkg_postinst () {
	bash-completion_pkg_postinst
}