[gentoo-commits] gentoo-x86 commit in dev-util/gource: gource-0.38.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/04/28 20:58:38

  Modified:             ChangeLog
  Added:                gource-0.38.ebuild
  Log:
  Version bump, thanks to Enrico.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 dev-util/gource/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gource/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gource/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gource/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/gource/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	21 Oct 2011 09:26:34 -0000	1.17
+++ ChangeLog	28 Apr 2012 20:58:38 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/gource
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/gource/ChangeLog,v 1.17 2011/10/21 09:26:34 flameeyes Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/gource/ChangeLog,v 1.18 2012/04/28 20:58:38 flameeyes Exp $
+
+*gource-0.38 (28 Apr 2012)
+
+  28 Apr 2012; Diego E. Pettenò <flameeyes@g.o> +gource-0.38.ebuild:
+  Version bump, thanks to Enrico.
 
 *gource-0.37 (21 Oct 2011)
 



1.1                  dev-util/gource/gource-0.38.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gource/gource-0.38.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/gource/gource-0.38.ebuild?rev=1.1&content-type=text/plain

Index: gource-0.38.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/gource/gource-0.38.ebuild,v 1.1 2012/04/28 20:58:37 flameeyes Exp $

EAPI=2

inherit autotools flag-o-matic versionator

MY_P=${P/_p/-}
MY_P=${MY_P/_/-}
MY_DATE=${PV/*_p}

DESCRIPTION="A software version control visualization tool"
HOMEPAGE="http://code.google.com/p/gource/"
SRC_URI="http://gource.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	>=media-libs/libsdl-1.2.10[opengl,X]
	>=media-libs/sdl-image-1.2[jpeg,png]
	dev-libs/libpcre:3
	>=media-libs/libpng-1.2
	virtual/jpeg
	media-libs/mesa
	media-fonts/freefont-ttf
	>=media-libs/glew-1.5
	dev-libs/tinyxml
	>=dev-libs/boost-1.46
	"
DEPEND="
	${RDEPEND}
	dev-util/pkgconfig
	media-libs/freetype:2
	>=media-libs/glm-0.9.3
	"

case ${PV} in
	*_beta*)
		my_v=$(get_version_component_range 1-3)
		my_v=${my_v//_/-}
		S="${WORKDIR}/${PN}-${my_v}" ;;
	*)
		S="${WORKDIR}/${PN}-$(get_version_component_range 1-2)" ;;
esac

src_prepare() {
	eautoreconf
}

src_configure() {
	# fix bug #386525
	# this enable gource to be compiled against dev-libs/tinyxml[stl]
	if has_version dev-libs/tinyxml[stl]; then
		append-cppflags -DTIXML_USE_STL;
	fi
	econf --enable-ttf-font-dir=/usr/share/fonts/freefont-ttf/ \
		--with-tinyxml
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	dodoc README ChangeLog THANKS || die "dodoc failed"
}