[gentoo-commits] gentoo-x86 commit in app-admin/ansible: ansible-9999.ebuild ChangeLog ansible-1.2.3.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    13/09/03 15:11:14

  Modified:             ansible-9999.ebuild ChangeLog
  Added:                ansible-1.2.3.ebuild
  Log:
  Version bump, wrt bug #482152. Sync live ebuild
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.12                 app-admin/ansible/ansible-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-9999.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-9999.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-9999.ebuild?r1=1.11&r2=1.12

Index: ansible-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-9999.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ansible-9999.ebuild	16 Jul 2013 12:23:02 -0000	1.11
+++ ansible-9999.ebuild	3 Sep 2013 15:11:13 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-9999.ebuild,v 1.11 2013/07/16 12:23:02 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-9999.ebuild,v 1.12 2013/09/03 15:11:13 pinkbyte Exp $
 
 EAPI="5"
 
@@ -37,19 +37,18 @@
 You have to create ansible hosts file!\n
 More info on http://ansible.cc/docs/gettingstarted.html"
 
-src_prepare() {
-	distutils-r1_src_prepare
+python_prepare_all() {
+	distutils-r1_python_prepare_all
 	# Skip tests which need ssh access
 	sed -i 's:$(NOSETESTS) -d -v:\0 -e \\(TestPlayBook.py\\|TestRunner.py\\):' Makefile || die "sed failed"
 }
 
-src_test() {
+python_test() {
 	make tests || die "tests failed"
 }
 
-src_install() {
-	distutils-r1_src_install
-	readme.gentoo_create_doc
+python_install_all() {
+	distutils-r1_python_install_all
 
 	doman docs/man/man1/*.1
 	dodoc -r examples
@@ -59,3 +58,8 @@
 
 	newenvd "${FILESDIR}"/${PN}.env 95ansible
 }
+
+src_install() {
+	distutils-r1_src_install
+	readme.gentoo_create_doc
+}



1.24                 app-admin/ansible/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	24 Aug 2013 05:22:39 -0000	1.23
+++ ChangeLog	3 Sep 2013 15:11:14 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/ansible
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.23 2013/08/24 05:22:39 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.24 2013/09/03 15:11:14 pinkbyte Exp $
+
+*ansible-1.2.3 (03 Sep 2013)
+
+  03 Sep 2013; Sergey Popov <pinkbyte@g.o> +ansible-1.2.3.ebuild,
+  ansible-9999.ebuild:
+  Version bump, wrt bug #482152. Sync live ebuild
 
   24 Aug 2013; Sergey Popov <pinkbyte@g.o> -ansible-1.0.ebuild,
   -ansible-1.1.ebuild:



1.1                  app-admin/ansible/ansible-1.2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.2.3.ebuild?rev=1.1&content-type=text/plain

Index: ansible-1.2.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-1.2.3.ebuild,v 1.1 2013/09/03 15:11:14 pinkbyte Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1 readme.gentoo

DESCRIPTION="Radically simple deployment, model-driven configuration management, and command execution framework"
HOMEPAGE="http://ansible.cc/"
SRC_URI="https://github.com/ansible/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

KEYWORDS="~amd64 ~x86"
LICENSE="GPL-3"
SLOT="0"
IUSE="test"

DEPEND="test? (
		dev-python/nose
		dev-vcs/git
	)"
RDEPEND="
	dev-python/jinja
	dev-python/pyyaml
	dev-python/paramiko
	net-misc/sshpass
	virtual/ssh
"

DOC_CONTENTS="You can define parameters through shell variables OR use config files
Examples of config files installed in /usr/share/doc/${P}/examples\n\n
You have to create ansible hosts file!\n
More info on http://ansible.cc/docs/gettingstarted.html"

python_prepare_all() {
	distutils-r1_python_prepare_all
	# Skip tests which need ssh access
	sed -i 's:$(NOSETESTS) -d -v:\0 -e \\(TestPlayBook.py\\|TestRunner.py\\):' Makefile || die "sed failed"
}

python_test() {
	make tests || die "tests failed"
}

python_install_all() {
	distutils-r1_python_install_all

	doman docs/man/man1/*.1
	dodoc -r examples
	docompress -x /usr/share/doc/${PF}/examples
	# Hint: do not install example config files into /etc
	# let this choice to user

	newenvd "${FILESDIR}"/${PN}.env 95ansible
}

src_install() {
	distutils-r1_src_install
	readme.gentoo_create_doc
}