[gentoo-commits] gentoo-x86 commit in net-wireless/gnome-bluetooth: ChangeLog gnome-bluetooth-3.12.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         14/04/27 18:11:41

  Modified:             ChangeLog
  Added:                gnome-bluetooth-3.12.0.ebuild
  Log:
  Version bump for Gnome 3.12.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.139                net-wireless/gnome-bluetooth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?rev=1.139&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?rev=1.139&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?r1=1.138&r2=1.139

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v
retrieving revision 1.138
retrieving revision 1.139
diff -u -r1.138 -r1.139
--- ChangeLog	30 Mar 2014 08:40:14 -0000	1.138
+++ ChangeLog	27 Apr 2014 18:11:41 -0000	1.139
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/gnome-bluetooth
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.138 2014/03/30 08:40:14 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.139 2014/04/27 18:11:41 eva Exp $
+
+*gnome-bluetooth-3.12.0 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@g.o>
+  +gnome-bluetooth-3.12.0.ebuild:
+  Version bump for Gnome 3.12.
 
   30 Mar 2014; Pacho Ramos <pacho@g.o> -gnome-bluetooth-3.8.2.1.ebuild,
   gnome-bluetooth-3.10.0.ebuild:



1.1                  net-wireless/gnome-bluetooth/gnome-bluetooth-3.12.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.12.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.12.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-bluetooth-3.12.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.12.0.ebuild,v 1.1 2014/04/27 18:11:41 eva Exp $

EAPI="5"
GCONF_DEBUG="yes"

inherit eutils gnome2 udev user

DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
HOMEPAGE="https://wiki.gnome.org/GnomeBluetooth"

LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
SLOT="2/13" # subslot = libgnome-bluetooth soname version
IUSE="+introspection"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

COMMON_DEPEND="
	>=dev-libs/glib-2.37.3:2
	>=x11-libs/gtk+-3.11.2:3[introspection?]
	virtual/udev
	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
"
RDEPEND="${COMMON_DEPEND}
	>=net-wireless/bluez-5
	x11-themes/gnome-icon-theme-symbolic
"
DEPEND="${COMMON_DEPEND}
	!net-wireless/bluez-gnome
	app-text/docbook-xml-dtd:4.1.2
	dev-libs/libxml2:2
	dev-util/gdbus-codegen
	>=dev-util/gtk-doc-am-1.9
	>=dev-util/intltool-0.40.0
	virtual/libudev
	virtual/pkgconfig
	x11-proto/xproto
"
# eautoreconf needs:
#	gnome-base/gnome-common

pkg_setup() {
	enewgroup plugdev
}

src_prepare() {
	# Regenerate gdbus-codegen files to allow using any glib version; bug #436236
	rm -v lib/bluetooth-client-glue.{c,h} || die
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		$(use_enable introspection) \
		--enable-documentation \
		--disable-desktop-update \
		--disable-icon-update \
		--disable-static \
		ITSTOOL=$(type -P true)
}

src_install() {
	gnome2_src_install
	udev_dorules "${FILESDIR}"/61-${PN}.rules
}

pkg_postinst() {
	gnome2_pkg_postinst
	if ! has_version sys-auth/consolekit[acl] && ! has_version sys-apps/systemd[acl] ; then
		elog "Don't forget to add yourself to the plugdev group "
		elog "if you want to be able to control bluetooth transmitter."
	fi
}