[gentoo-commits] gentoo-x86 commit in net-print/splix: ChangeLog splix-2.0.0_p20110219.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    11/03/29 10:04:40

  Modified:             ChangeLog
  Added:                splix-2.0.0_p20110219.ebuild
  Log:
  Update to a snapshot version, adds support for a series of newer printer and other fixes, fixes bug #359823
  
  (Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 net-print/splix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/splix/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/splix/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/splix/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/splix/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	28 Mar 2011 17:32:00 -0000	1.17
+++ ChangeLog	29 Mar 2011 10:04:40 -0000	1.18
@@ -1,6 +1,13 @@
 # ChangeLog for net-print/splix
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/splix/ChangeLog,v 1.17 2011/03/28 17:32:00 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/splix/ChangeLog,v 1.18 2011/03/29 10:04:40 voyageur Exp $
+
+*splix-2.0.0_p20110219 (29 Mar 2011)
+
+  29 Mar 2011; Bernard Cafarelli <voyageur@g.o>
+  +splix-2.0.0_p20110219.ebuild:
+  Update to a snapshot version, adds support for a series of newer printer and
+  other fixes, fixes bug #359823
 
   28 Mar 2011; Christoph Mende <angelos@g.o> splix-2.0.0.ebuild:
   Stable on amd64 wrt bug #360567



1.1                  net-print/splix/splix-2.0.0_p20110219.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/splix/splix-2.0.0_p20110219.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/splix/splix-2.0.0_p20110219.ebuild?rev=1.1&content-type=text/plain

Index: splix-2.0.0_p20110219.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/splix/splix-2.0.0_p20110219.ebuild,v 1.1 2011/03/29 10:04:40 voyageur Exp $

EAPI=2
inherit eutils toolchain-funcs

DESCRIPTION="A set of CUPS printer drivers for SPL (Samsung Printer Language) printers"
HOMEPAGE="http://splix.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~voyageur/distfiles/${P}.tar.bz2
	http://splix.ap2c.org/samsung_cms.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+jbig"

DEPEND="|| ( >=net-print/cups-1.4.0 net-print/cupsddk )
	jbig? ( media-libs/jbigkit )"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${PN}

src_prepare() {
	# Honor LDFLAGS
	sed -e "/[a-z]_LDFLAGS/s/:=.*/:= $\{LDFLAGS\}/" -i module.mk \
		|| die "module.mk sed failed"
	# Correct link comand, do not strip on install
	sed -e "s/g++/$\{LINKER\}/" -e "/install/s/-s //" -i rules.mk \
		|| die "rules.mk sed failed"
}

src_compile() {
	local options="MODE=optimized"
	use jbig || options="${options} DISABLE_JBIG=1"
	emake ${options} CXX="$(tc-getCXX)" \
		OPTIM_CFLAGS="${CFLAGS}" OPTIM_CXXFLAGS="${CXXFLAGS}" \
		|| die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	gzip "${D}"/$(cups-config --datadir)/model/*/*.ppd || die "ppd gzip failed"

	insinto $(cups-config --datadir)/model/samsung
	doins -r "${WORKDIR}"/cms
}

pkg_postinst() {
	ewarn "You *MUST* make sure that the PPD files that CUPS is using"
	ewarn "for actually installed printers are updated if you upgraded"
	ewarn "from a previous version of splix!"
	ewarn "Otherwise you will be unable to print (your printer might"
	ewarn "spit out blank pages etc.)."
	ewarn "To do that, simply delete the corresponding PPD file in"
	ewarn "/etc/cups/ppd/, click on 'Modify Printer' belonging to the"
	ewarn "corresponding printer in the CUPS webinterface (usually"
	ewarn "reachable via http://localhost:631/) and choose the correct"
	ewarn "printer make and model, for example:"
	ewarn "'Samsung' -> 'Samsung ML-1610, 1.0 (en)'"
}