[gentoo-commits] repo/gentoo:master commit in: dev-libs/igraph/

[Michael Orlitzky]

commit:     e46b357454a3ad89773f243b512757587f130cb6
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Fri Jun  3 02:09:03 2016 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Fri Jun  3 13:16:26 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e46b3574

dev-libs/igraph: new revision with EAPI=6 and ~x86 keywords.

The main reason for this revision is to add the ~x86 keywords, which
are blocking bug 573728. In the process, the EAPI was updated and some
necessary refactoring done. The HOMEPAGE/SRC_URI was also updated.

Gentoo-Bug: 573730

Package-Manager: portage-2.2.28

 dev-libs/igraph/igraph-0.7.1-r1.ebuild | 52 ----------------------------------
 dev-libs/igraph/igraph-0.7.1-r2.ebuild | 47 ++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+), 52 deletions(-)

diff --git a/dev-libs/igraph/igraph-0.7.1-r1.ebuild b/dev-libs/igraph/igraph-0.7.1-r1.ebuild
deleted file mode 100644
index d89f8e9..0000000
--- a/dev-libs/igraph/igraph-0.7.1-r1.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-AUTOTOOLS_AUTORECONF=true
-
-inherit autotools-utils toolchain-funcs
-
-DESCRIPTION="Creating and manipulating undirected and directed graphs"
-HOMEPAGE="http://igraph.sourceforge.net/index.html"
-SRC_URI="mirror://sourceforge/project/${PN}/C%20library/${PV}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0/0"
-KEYWORDS="~amd64"
-IUSE="debug gmp static-libs"
-
-RDEPEND="
-	dev-libs/libxml2
-	>=sci-libs/arpack-3
-	virtual/blas
-	virtual/lapack
-	>=sci-libs/cxsparse-3
-	sci-mathematics/glpk
-	gmp? ( dev-libs/gmp )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-PATCHES=( "${FILESDIR}"/${P}-unbundle.patch )
-
-src_prepare() {
-#	rm -rf src/{cs,f2c,lapack,f2c.h} optional/glpk || die
-#	rm -rf src/cs optional/glpk || die
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	tc-export PKG_CONFIG
-	local myeconfargs=(
-		$(use_enable gmp)
-		$(use_enable debug)
-		--disable-tls
-		--with-external-arpack
-		--with-external-blas
-		--with-external-lapack
-		--with-external-f2c
-		--with-external-glpk
-	)
-	autotools-utils_src_configure
-}

diff --git a/dev-libs/igraph/igraph-0.7.1-r2.ebuild b/dev-libs/igraph/igraph-0.7.1-r2.ebuild
new file mode 100644
index 0000000..3597da3
--- /dev/null
+++ b/dev-libs/igraph/igraph-0.7.1-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Creating and manipulating undirected and directed graphs"
+HOMEPAGE="http://www.igraph.org/"
+SRC_URI="http://www.igraph.org/nightly/get/c/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug gmp"
+
+RDEPEND="
+	dev-libs/libxml2
+	>=sci-libs/arpack-3
+	virtual/blas
+	virtual/lapack
+	>=sci-libs/cxsparse-3
+	sci-mathematics/glpk
+	gmp? ( dev-libs/gmp:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${P}-unbundle.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export PKG_CONFIG
+	econf \
+		$(use_enable gmp) \
+		$(use_enable debug) \
+		--disable-tls \
+		--with-external-arpack \
+		--with-external-blas \
+		--with-external-lapack \
+		--with-external-f2c \
+		--with-external-glpk
+}