[gentoo-commits] proj/kde:master commit in: kde-apps/ark/

[Andreas Sturmlechner]

commit:     e4dd38538426511caf892c9362ffa5ce1cd5be4c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  2 13:24:19 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Mar  2 13:32:42 2023 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=e4dd3853

kde-apps/ark: drop 22.12.49.9999

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/ark/ark-22.12.49.9999.ebuild | 80 -----------------------------------
 1 file changed, 80 deletions(-)

diff --git a/kde-apps/ark/ark-22.12.49.9999.ebuild b/kde-apps/ark/ark-22.12.49.9999.ebuild
deleted file mode 100644
index c0ca377a20..0000000000
--- a/kde-apps/ark/ark-22.12.49.9999.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="optional"
-KFMIN=5.101.0
-QTMIN=5.15.5
-VIRTUALX_REQUIRED="test"
-inherit ecm gear.kde.org optfeature
-
-DESCRIPTION="File archiver by KDE"
-HOMEPAGE="https://apps.kde.org/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS=""
-IUSE="zip"
-
-RDEPEND="
-	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.6.0:= )
-"
-DEPEND="${RDEPEND}
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	test? ( >=dev-libs/libzip-1.6.0:= )
-"
-# app-arch/rar is binary only
-BDEPEND="
-	sys-devel/gettext
-	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# bug 822177: may segfault or hang indefinitely
-		-E "(kerfuffle-addtoarchivetest)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "rar archive creation/extraction" "app-arch/rar"
-		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
-		optfeature "7-Zip archive support" "app-arch/p7zip"
-		optfeature "lrz archive support" "app-arch/lrzip"
-		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
-	fi
-	ecm_pkg_postinst
-}