[gentoo-commits] repo/gentoo:master commit in: dev-python/nose/

[Michał Górny]

commit:     11ee46ed7e402d1f067e4c3a991e3a95a0ad8507
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 16 08:37:00 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov 16 08:45:40 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=11ee46ed

dev-python/nose: Remove the live ebuild

The project is practically dead, and the live ebuild is just a burden.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nose/nose-9999.ebuild | 86 ----------------------------------------
 1 file changed, 86 deletions(-)

diff --git a/dev-python/nose/nose-9999.ebuild b/dev-python/nose/nose-9999.ebuild
deleted file mode 100644
index 03c347f62ba..00000000000
--- a/dev-python/nose/nose-9999.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1 git-r3
-
-DESCRIPTION="Unittest extension with automatic test suite discovery and easy test authoring"
-HOMEPAGE="
-	https://pypi.org/project/nose/
-	https://nose.readthedocs.io/en/latest/
-	https://github.com/nose-devs/nose"
-SRC_URI=""
-EGIT_REPO_URI="https://github.com/nose-devs/${PN}.git"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS=""
-IUSE="doc examples test"
-
-REQUIRED_USE="
-	doc? ( || ( $(python_gen_useflags 'python2*') ) )"
-
-RDEPEND="
-	dev-python/coverage[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}
-	doc? ( >=dev-python/sphinx-0.6[${PYTHON_USEDEP}] )
-	test? ( $(python_gen_cond_dep 'dev-python/twisted[${PYTHON_USEDEP}]' python2_7 python3_{5,6}) )"
-
-pkg_setup() {
-	use doc && DISTUTILS_ALL_SUBPHASE_IMPLS=( 'python2*' )
-}
-
-python_prepare_all() {
-	# Tests need to be converted, and they don't respect BUILD_DIR.
-	use test && DISTUTILS_IN_SOURCE_BUILD=1
-
-	# Disable tests requiring network connection.
-	sed \
-		-e "s/test_resolve/_&/g" \
-		-e "s/test_raises_bad_return/_&/g" \
-		-e "s/test_raises_twisted_error/_&/g" \
-		-i unit_tests/test_twisted.py || die "sed failed"
-	# Disable versioning of nosetests script to avoid collision with
-	# versioning performed by the eclass.
-	sed -e "/'nosetests%s = nose:run_exit' % py_vers_tag,/d" \
-		-i setup.py || die "sed2 failed"
-
-	# Prevent un-needed d'loading during doc build
-	sed -e "s/, 'sphinx.ext.intersphinx'//" -i doc/conf.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	local add_targets=()
-
-	if use test; then
-		add_targets+=( egg_info )
-		python_is_python3 && add_targets+=( build_tests )
-	fi
-
-	distutils-r1_python_compile ${add_targets[@]}
-}
-
-python_compile_all() {
-	use doc && emake -C doc html
-}
-
-python_test() {
-	"${PYTHON}" selftest.py -v || die "Tests fail with ${EPYTHON}"
-}
-
-python_install() {
-	distutils-r1_python_install --install-data "${EPREFIX}/usr/share"
-}
-
-python_install_all() {
-	use examples && dodoc -r examples
-	use doc && HTML_DOCS=( doc/.build/html/. )
-	distutils-r1_python_install_all
-}