1 |
commit: 965e22e1e9aec71fa687c3c40f822a0f060a507d |
2 |
Author: Michał Górny <mgorny <AT> gentoo <DOT> org> |
3 |
AuthorDate: Fri Aug 20 05:08:46 2021 +0000 |
4 |
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org> |
5 |
CommitDate: Fri Aug 20 08:50:57 2021 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=965e22e1 |
7 |
|
8 |
dev-python/aesara: Bump to 2.2.0 |
9 |
|
10 |
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org> |
11 |
|
12 |
dev-python/aesara/Manifest | 1 + |
13 |
dev-python/aesara/aesara-2.2.0.ebuild | 70 +++++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 71 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/aesara/Manifest b/dev-python/aesara/Manifest |
17 |
index 7b7fc949363..7075b24fde3 100644 |
18 |
--- a/dev-python/aesara/Manifest |
19 |
+++ b/dev-python/aesara/Manifest |
20 |
@@ -1,3 +1,4 @@ |
21 |
DIST aesara-rel-2.0.12.tar.gz 8154749 BLAKE2B 0e39102e985e9f9ed49f65c76389d76702b5d8fbe8c3e1130c61dce7c43eb70f5c73fd3557ff9aeaa1d186b33bb5803a04a4a5b0ce41076af7e923d05ce3353d SHA512 e68f5ce0c64a678219421a0bfc957d1594dc34c887af6f6373c00888387e5da83dec44b68b9309146ae2fd60c0677039980a87ee87ecc0ad3db2fbc80213cc34 |
22 |
DIST aesara-rel-2.1.2.tar.gz 8167162 BLAKE2B 727bdf6fb9765c8b60da585595ed7203071490c1dfc0895428ae3efe4a1e74a14bbdf2a76128a6840dedeabdfc997fd297dec23ff517247452433cbdc9449b9a SHA512 22ebd1290a0727f2cf1e106770c872d5f1d785c6946b8e4debcc29a34fddceccb11f0ec81850fd93dbff556aa300bf2ec1bd6eef1297d93e194ff832b442c453 |
23 |
DIST aesara-rel-2.1.3.tar.gz 8170822 BLAKE2B dbbc4a453c5d7f9cd4ab2c925dd9293e835db23100686a8d7ab2c47182b1bc05f883eeb60d6f47f8f34e4187f3ac07b632cde43fe82a99e2145a2f699a2b3582 SHA512 52d1724eb7b3c9bae4bdbf1735db9ef96cdfa94f3e2281b255201d0baba260fe31f78c00719a53ce3c59ea9c66ff218d8acd7bc012b386942f29806c07ffc466 |
24 |
+DIST aesara-rel-2.2.0.tar.gz 8164718 BLAKE2B 3a3c0fe8db807df8932f92b292b7a06a1d8880e136b09a65a66e861d04e02367bd6d688ca41d2d399d97a0543f8664533c64072ae6f9ced49220643107aea98e SHA512 be6fc667041fb6dda770785629afd3e286442092d263200e9fc3ac635ea027e21ae37041f0b5c5e318956a042c36a7aa5e671f4f35a8e0faef604d39fa68d122 |
25 |
|
26 |
diff --git a/dev-python/aesara/aesara-2.2.0.ebuild b/dev-python/aesara/aesara-2.2.0.ebuild |
27 |
new file mode 100644 |
28 |
index 00000000000..3148f85f3cf |
29 |
--- /dev/null |
30 |
+++ b/dev-python/aesara/aesara-2.2.0.ebuild |
31 |
@@ -0,0 +1,70 @@ |
32 |
+# Copyright 2021 Gentoo Authors |
33 |
+# Distributed under the terms of the GNU General Public License v2 |
34 |
+ |
35 |
+EAPI=8 |
36 |
+ |
37 |
+PYTHON_COMPAT=( python3_{8..10} ) |
38 |
+inherit distutils-r1 optfeature |
39 |
+ |
40 |
+MY_P=aesara-rel-${PV} |
41 |
+DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays" |
42 |
+HOMEPAGE="https://github.com/aesara-devs/aesara" |
43 |
+SRC_URI="https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz" |
44 |
+S="${WORKDIR}/${MY_P}" |
45 |
+ |
46 |
+LICENSE="BSD" |
47 |
+SLOT="0" |
48 |
+KEYWORDS="~amd64 ~arm ~arm64 ~x86" |
49 |
+ |
50 |
+RDEPEND=" |
51 |
+ dev-python/filelock[${PYTHON_USEDEP}] |
52 |
+ >=dev-python/numpy-1.17.0[${PYTHON_USEDEP}] |
53 |
+ dev-python/six[${PYTHON_USEDEP}] |
54 |
+ dev-python/scipy[${PYTHON_USEDEP}]" |
55 |
+BDEPEND=" |
56 |
+ test? ( |
57 |
+ dev-python/pytest-xdist[${PYTHON_USEDEP}] |
58 |
+ )" |
59 |
+ |
60 |
+distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme' |
61 |
+distutils_enable_tests pytest |
62 |
+ |
63 |
+python_prepare_all() { |
64 |
+ sed -i -e "s/tests.\*/tests\*/" setup.py || die |
65 |
+ |
66 |
+ distutils-r1_python_prepare_all |
67 |
+} |
68 |
+ |
69 |
+python_test() { |
70 |
+ local exclude=( |
71 |
+ # speed tests are unreliable |
72 |
+ tests/scan/test_basic.py::test_speed |
73 |
+ tests/scan/test_basic.py::test_speed_rnn |
74 |
+ tests/scan/test_basic.py::test_speed_batchrnn |
75 |
+ tests/link/test_vm.py::test_speed |
76 |
+ tests/link/test_vm.py::test_speed_lazy |
77 |
+ tests/tensor/test_gc.py::test_merge_opt_runtime |
78 |
+ |
79 |
+ # rounding problem? |
80 |
+ # https://github.com/aesara-devs/aesara/issues/477 |
81 |
+ tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good |
82 |
+ tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good |
83 |
+ ) |
84 |
+ |
85 |
+ distutils_install_for_testing |
86 |
+ # we do not package numba |
87 |
+ epytest ${exclude[@]/#/--deselect } \ |
88 |
+ --ignore tests/link/test_numba.py \ |
89 |
+ -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" |
90 |
+} |
91 |
+ |
92 |
+# https://dev.gentoo.org/~mgorny/python-guide/concept.html#packaging-pkgutil-style-namespaces-in-gentoo |
93 |
+python_install() { |
94 |
+ rm "${BUILD_DIR}"/lib/bin/__init__.py || die |
95 |
+ distutils-r1_python_install |
96 |
+} |
97 |
+ |
98 |
+pkg_postinst() { |
99 |
+ optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk |
100 |
+ optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda |
101 |
+} |