[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: alsa-utils-1.0.25-r2.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/04/08 19:43:31

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.25-r2.ebuild
  Log:
  Make sure that the minimal USE flag also does not install the alsaconf script, not just ignore the dependency.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.323                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.323&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.323&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.322&r2=1.323

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.322
retrieving revision 1.323
diff -u -r1.322 -r1.323
--- ChangeLog	1 Apr 2012 15:13:17 -0000	1.322
+++ ChangeLog	8 Apr 2012 19:43:31 -0000	1.323
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.322 2012/04/01 15:13:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.323 2012/04/08 19:43:31 flameeyes Exp $
+
+*alsa-utils-1.0.25-r2 (08 Apr 2012)
+
+  08 Apr 2012; Diego E. Pettenò <flameeyes@g.o>
+  +alsa-utils-1.0.25-r2.ebuild:
+  Make sure that the minimal USE flag also does not install the alsaconf script,
+  not just ignore the dependency.
 
   01 Apr 2012; Raúl Porcel <armin76@g.o> alsa-utils-1.0.25-r1.ebuild:
   alpha/ia64/sh/sparc stable wrt #406101



1.1                  media-sound/alsa-utils/alsa-utils-1.0.25-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.25-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.25-r2.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.25-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.25-r2.ebuild,v 1.1 2012/04/08 19:43:31 flameeyes Exp $

EAPI=4
inherit base systemd

MY_P=${P/_rc/rc}

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2
	mirror://alsaproject/driver/alsa-driver-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="doc nls minimal"

COMMON_DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-1.0.25
	media-libs/libsamplerate"
DEPEND="${COMMON_DEPEND}
	doc? ( app-text/xmlto )"
RDEPEND="${COMMON_DEPEND}
	!minimal? ( sys-apps/pciutils )"

S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}/${PN}-1.0.23-modprobe.d.patch"
"${FILESDIR}/${P}-separate-usr-var-fs.patch"
)

src_configure() {
	local myconf=""
	use doc || myconf="--disable-xmlto"

	econf ${myconf} \
		$(use_enable nls) \
		$(use_enable !minimal alsaconf) \
		"$(systemd_with_unitdir)"
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc ${ALSA_UTILS_DOCS} || die

	newbin "${WORKDIR}/alsa-driver-${PV}/utils/alsa-info.sh" \
		alsa-info

	newinitd "${FILESDIR}/alsasound.initd-r5" alsasound
	newconfd "${FILESDIR}/alsasound.confd-r4" alsasound
	insinto /etc/modprobe.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa.conf

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "saving and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
	ewarn "The ALSA core should be built into the kernel or loaded through other"
	ewarn "means. There is no longer any modular auto(un)loading in alsa-utils."
	echo
	if use minimal; then
		ewarn "The minimal use flag disables the dependency on pciutils that"
		ewarn "is needed by alsaconf at runtime."
	fi
}