[gentoo-commits] repo/gentoo:master commit in: app-emulation/open-vm-tools/

[Mike Gilbert]

commit:     a8e25006bbf77be35b5f934c9034905ef5b0fbbd
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 26 00:52:57 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun Sep 26 00:52:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8e25006

app-emulation/open-vm-tools: drop 11.2.0_p16938113-r4

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 app-emulation/open-vm-tools/Manifest               |   1 -
 .../open-vm-tools-11.2.0_p16938113-r4.ebuild       | 143 ---------------------
 2 files changed, 144 deletions(-)

diff --git a/app-emulation/open-vm-tools/Manifest b/app-emulation/open-vm-tools/Manifest
index 879bf9f6a32..95cb9974c3b 100644
--- a/app-emulation/open-vm-tools/Manifest
+++ b/app-emulation/open-vm-tools/Manifest
@@ -1,2 +1 @@
-DIST open-vm-tools-11.2.0-16938113.tar.gz 4050857 BLAKE2B b0e5e1e985d9f3d50dbbb8a4a7939d37d8968f0aa15e6d7200b7ec8511bd059d3a78a4ddd763d22965dc6da614d156e6b7ee23af73490f8bbf8e1dc2664041d3 SHA512 c950d6e8ba5218dd40e845f3c2b09eeb640ef0d33c7ea1671164027927e062dcf0b4745f6e4515a7495ec20a6d06a8fbf700819f6211073194b5ef97d7be441d
 DIST open-vm-tools-11.2.5-17337674.tar.gz 4057528 BLAKE2B 2adc5179e09a4bb501fe12c9e6dea7fee106516fd250899170a8fb3bcefb9b576136a82e4c3d3a73217b44aba8880728bb3588cedd715529f9b2991f0156ac84 SHA512 b6d4bc6522418ec7a881752181ad9240e535854df492e758abf3996c6afe245466ffbff60cc1b6cdff5cf731b5769c9f9cb96aed29f0b788d0eef05f91fcf8ab

diff --git a/app-emulation/open-vm-tools/open-vm-tools-11.2.0_p16938113-r4.ebuild b/app-emulation/open-vm-tools/open-vm-tools-11.2.0_p16938113-r4.ebuild
deleted file mode 100644
index d835f525509..00000000000
--- a/app-emulation/open-vm-tools/open-vm-tools-11.2.0_p16938113-r4.ebuild
+++ /dev/null
@@ -1,143 +0,0 @@
-# Copyright 2007-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools linux-info pam systemd
-
-DESCRIPTION="Opensourced tools for VMware guests"
-HOMEPAGE="https://github.com/vmware/open-vm-tools"
-MY_P="${PN}-${PV/_p/-}"
-SRC_URI="https://github.com/vmware/open-vm-tools/releases/download/stable-${PV%_p*}/${MY_P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="X +deploypkg +dnet doc +fuse gtkmm +icu multimon pam +resolutionkms +ssl static-libs +vgauth"
-REQUIRED_USE="
-	multimon? ( X )
-	vgauth? ( ssl )
-"
-
-RDEPEND="
-	dev-libs/glib
-	net-libs/libtirpc
-	deploypkg? ( dev-libs/libmspack )
-	fuse? ( sys-fs/fuse:0 )
-	pam? ( sys-libs/pam )
-	!pam? ( virtual/libcrypt:= )
-	ssl? ( dev-libs/openssl:0= )
-	vgauth? (
-		dev-libs/libxml2
-		dev-libs/xmlsec
-	)
-	X? (
-		x11-libs/libXext
-		multimon? ( x11-libs/libXinerama )
-		x11-libs/libXi
-		x11-libs/libXrender
-		x11-libs/libXrandr
-		x11-libs/libXtst
-		x11-libs/libSM
-		x11-libs/libXcomposite
-		x11-libs/gdk-pixbuf-xlib
-		x11-libs/gtk+:3
-		gtkmm? (
-			dev-cpp/gtkmm:3.0
-			dev-libs/libsigc++:2
-		)
-	)
-	dnet? ( dev-libs/libdnet )
-	icu? ( dev-libs/icu:= )
-	resolutionkms? (
-		x11-libs/libdrm[video_cards_vmware]
-		virtual/libudev
-	)
-"
-
-DEPEND="${RDEPEND}
-	net-libs/rpcsvc-proto
-"
-
-BDEPEND="
-	dev-util/glib-utils
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-"
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
-	"${FILESDIR}/10.1.0-mount.vmhgfs.patch"
-	"${FILESDIR}/10.1.0-Werror.patch"
-)
-
-pkg_setup() {
-	local CONFIG_CHECK="~VMWARE_BALLOON ~VMWARE_PVSCSI ~VMXNET3"
-	use X && CONFIG_CHECK+=" ~DRM_VMWGFX"
-	kernel_is -lt 3 9 || CONFIG_CHECK+=" ~VMWARE_VMCI ~VMWARE_VMCI_VSOCKETS"
-	kernel_is -lt 3 || CONFIG_CHECK+=" ~FUSE_FS"
-	kernel_is -lt 5 5 || CONFIG_CHECK+=" ~X86_IOPL_IOPERM"
-	linux-info_pkg_setup
-}
-
-src_prepare() {
-	eapply -p2 "${PATCHES[@]}"
-	eapply_user
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		--without-root-privileges
-		$(use_enable multimon)
-		$(use_with X x)
-		$(use_with X gtk3)
-		$(use_with gtkmm gtkmm3)
-		$(use_enable doc docs)
-		--disable-tests
-		$(use_enable resolutionkms)
-		$(use_enable static-libs static)
-		$(use_enable deploypkg)
-		$(use_with pam)
-		$(use_enable vgauth)
-		$(use_with dnet)
-		$(use_with icu)
-	)
-	# Avoid a bug in configure.ac
-	use ssl || myeconfargs+=( --without-ssl )
-
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-	find "${ED}" -name '*.la' -delete || die
-
-	if use pam; then
-		rm "${ED}"/etc/pam.d/vmtoolsd || die
-		pamd_mimic_system vmtoolsd auth account
-	fi
-
-	newinitd "${FILESDIR}/open-vm-tools.initd" vmware-tools
-	newconfd "${FILESDIR}/open-vm-tools.confd" vmware-tools
-
-	if use vgauth; then
-		systemd_newunit "${FILESDIR}"/vmtoolsd.vgauth.service vmtoolsd.service
-		systemd_dounit "${FILESDIR}"/vgauthd.service
-	else
-		systemd_dounit "${FILESDIR}"/vmtoolsd.service
-	fi
-
-	# Replace mount.vmhgfs with a wrapper
-	mv "${ED}"/usr/sbin/{mount.vmhgfs,hgfsmounter} || die
-	dosbin "${FILESDIR}/mount.vmhgfs"
-
-	# Make fstype = vmhgfs-fuse work in fstab
-	dosym vmhgfs-fuse /usr/bin/mount.vmhgfs-fuse
-
-	if use X; then
-		fperms 4711 /usr/bin/vmware-user-suid-wrapper
-		dobin scripts/common/vmware-xdg-detect-de
-	fi
-}