[gentoo-commits] gentoo-x86 commit in games-emulation/raine: ChangeLog raine-0.50.7.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    08/02/05 00:16:06

  Modified:             ChangeLog
  Added:                raine-0.50.7.ebuild
  Log:
  version bump
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.19                 games-emulation/raine/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/raine/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/raine/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/raine/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/raine/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	11 Jan 2008 19:12:23 -0000	1.18
+++ ChangeLog	5 Feb 2008 00:16:06 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for games-emulation/raine
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/raine/ChangeLog,v 1.18 2008/01/11 19:12:23 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/raine/ChangeLog,v 1.19 2008/02/05 00:16:06 mr_bones_ Exp $
+
+*raine-0.50.7 (05 Feb 2008)
+
+  05 Feb 2008; Michael Sterrett <mr_bones_@g.o> +raine-0.50.7.ebuild:
+  version bump
 
 *raine-0.50.6 (11 Jan 2008)
 



1.1                  games-emulation/raine/raine-0.50.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/raine/raine-0.50.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-emulation/raine/raine-0.50.7.ebuild?rev=1.1&content-type=text/plain

Index: raine-0.50.7.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/raine/raine-0.50.7.ebuild,v 1.1 2008/02/05 00:16:06 mr_bones_ Exp $

inherit versionator games

MY_PV=$(replace_version_separator 3 '-')

DESCRIPTION="R A I N E  M680x0 Arcade Emulation"
HOMEPAGE="http://www.rainemu.com/"
SRC_URI="http://www.rainemu.com/html/archive/raines-${MY_PV}.tar.bz2
	http://www.rainemu.com/html/archive/rainedocs.zip
	http://www.rainemu.com/html/archive/icons.zip"

LICENSE="Artistic"
SLOT="0"
KEYWORDS="~x86"
IUSE="static"

RDEPEND="media-libs/allegro
	media-libs/libsdl
	sys-libs/zlib
	media-libs/sdl-image
	media-libs/sdl-ttf"
DEPEND="${RDEPEND}
	dev-lang/nasm
	app-arch/unzip"

S=${WORKDIR}/${PN}-$(get_version_component_range -3)

src_unpack() {
	unpack ${A}
	cd "${S}"
	echo > detect-cpu
	echo > cpuinfo
	sed -i \
		-e "/prefix =/s:/usr::" \
		-e "s:nasm -r:echo nasm:" \
		-e "/bindir/s:=.*:=\$(DESTDIR)${GAMES_BINDIR}:" \
		-e "/sharedir =/s:=.*:=\$(DESTDIR)${GAMES_DATADIR}:" \
		-e "/mandir/s:=.*:=\$(DESTDIR)/usr/share/man/man6:" \
		makefile \
		|| die "sed failed"
}

src_compile() {
	local myopts=
	use static \
		&& myopts="${myopts} STATIC=1" \
		|| myopts="${myopts} STATIC="
	emake \
		_MARCH="${CFLAGS}" \
		${myopts} || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	keepdir "${GAMES_DATADIR}"/${PN}/{roms,artwork,emudx}
	dodoc "${WORKDIR}/raine.txt"

	insinto /usr/share/icons
	doins "${WORKDIR}/"*.png
	make_desktop_entry raine Raine Raine48x48
	prepgamesdirs
}



-- 
gentoo-commits@l.g.o mailing list