[gentoo-commits] repo/proj/guru:dev commit in: media-fonts/3270font/

[Alessandro Barbieri]

commit:     ecf2cb61bdb97d0d498ac3348324166f694292d3
Author:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
AuthorDate: Thu Mar 31 20:49:20 2022 +0000
Commit:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
CommitDate: Thu Mar 31 21:35:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=ecf2cb61

media-fonts/3270font: add 2.3.1

Signed-off-by: Alessandro Barbieri <lssndrbarbieri <AT> gmail.com>

 media-fonts/3270font/3270font-2.3.1.ebuild | 61 ++++++++++++++++++++++++++++++
 media-fonts/3270font/Manifest              |  1 +
 2 files changed, 62 insertions(+)

diff --git a/media-fonts/3270font/3270font-2.3.1.ebuild b/media-fonts/3270font/3270font-2.3.1.ebuild
new file mode 100644
index 000000000..ef8fcf268
--- /dev/null
+++ b/media-fonts/3270font/3270font-2.3.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit font python-any-r1
+
+DESCRIPTION="A IBM 3270 Terminal font in a modern format"
+HOMEPAGE="https://github.com/rbanffy/3270font"
+SRC_URI="https://github.com/rbanffy/3270font/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD CC-BY-SA-3.0 GPL-3 OFL"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+PROPERTIES="test_network"
+DOCS=( CHANGELOG.md README.md  )
+HTML_DOCS=( "DESCRIPTION.en_us.html" )
+PATCHES=(
+	"${FILESDIR}/remove-useless-tests.patch"
+	"${FILESDIR}/${PN}-2.3.0-correctly-pass-options.patch"
+)
+
+DEPEND="
+	${PYTHON_DEPS}
+	media-gfx/fontforge
+	test? (
+		$(python_gen_any_dep '
+			dev-python/ipdb[${PYTHON_USEDEP}]
+			dev-python/pillow[${PYTHON_USEDEP}]
+			dev-util/gftools[${PYTHON_SINGLE_USEDEP}]
+			media-gfx/fontbakery[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+FONT_S="${S}/build"
+FONT_SUFFIX="otf ttf pfm woff"
+
+python_check_deps() {
+	has_version -d "dev-python/ipdb[${PYTHON_USEDEP}]" && \
+	has_version -d "dev-python/pillow[${PYTHON_USEDEP}]" && \
+	has_version -d "dev-util/gftools[${PYTHON_SINGLE_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_compile() {
+	emake font
+}
+
+src_test() {
+	emake test
+	emake fbchecks
+}

diff --git a/media-fonts/3270font/Manifest b/media-fonts/3270font/Manifest
index 28b5cd17c..388e35cab 100644
--- a/media-fonts/3270font/Manifest
+++ b/media-fonts/3270font/Manifest
@@ -1 +1,2 @@
 DIST 3270font-2.3.0.tar.gz 520106 BLAKE2B e3ece6a0f476d20bf4135057739a73deee49050b6be9b4bd3731b228729f622d059c53a122a266332e02e71af08dc6b13f215358dc275edd91247e3119d249be SHA512 26d1a32990b0ea8395959ed37d7acc76f1f1d160488ff6e96bb39fc8ca952339c09ed06cb0783a69b6ef6545be72ed63665af3584f79852fe0a813301f77ea7d
+DIST 3270font-2.3.1.tar.gz 526018 BLAKE2B c39f71df9f0a597ff3c32ec320f007af6508b0d8d6b68a3a8d621f5484ddc78334d6b73161f9d11e2f75855678f882e500bd698b87b5caa1e51125d763c530e8 SHA512 df1d0909d6acff0b796f236d177828e9e9ded7b771c9cb675a63a7689c0ab1a159d44ab641aa4bca91e8548972a7bca38b583c56ea0c09e15a6b1f1ede798324