[gentoo-commits] repo/gentoo:master commit in: dev-python/uvicorn/

[Michał Górny]

commit:     4da936898504bb823dd637553a2e5678a3cfea47
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 16 17:36:48 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun 16 18:56:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4da93689

dev-python/uvicorn: Add missing test-dep on python-dotenv

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild | 45 +++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild b/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild
new file mode 100644
index 00000000000..3901bfce5fe
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.14.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="https://www.uvicorn.org/"
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	>=dev-python/click-7[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.8[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' python3_7)
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		>=dev-python/websockets-9.1[${PYTHON_USEDEP}]
+		dev-python/wsproto[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# watchgod is not in the tree
+	sed -e '/^from uvicorn.supervisors.watchgodreload/d' \
+		-e 's/, WatchGodReload//' \
+		-i tests/supervisors/test_reload.py
+	distutils-r1_python_prepare_all
+}