[gentoo-commits] gentoo-x86 commit in www-client/arora: ChangeLog arora-0.6.ebuild

[Ben de Groot (yngwin)]

yngwin      09/03/31 05:46:05

  Modified:             ChangeLog
  Added:                arora-0.6.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.11                 www-client/arora/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	25 Mar 2009 07:08:20 -0000	1.10
+++ ChangeLog	31 Mar 2009 05:46:05 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/arora
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.10 2009/03/25 07:08:20 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.11 2009/03/31 05:46:05 yngwin Exp $
+
+*arora-0.6 (31 Mar 2009)
+
+  31 Mar 2009; Ben de Groot <yngwin@g.o> +arora-0.6.ebuild:
+  New release. The en_US locale is no longer optional.
 
   25 Mar 2009; Ben de Groot <yngwin@g.o> metadata.xml:
   Transfer maintainership to qt herd



1.1                  www-client/arora/arora-0.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/arora-0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/arora-0.6.ebuild?rev=1.1&content-type=text/plain

Index: arora-0.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/arora/arora-0.6.ebuild,v 1.1 2009/03/31 05:46:05 yngwin Exp $

EAPI=2
inherit eutils qt4

DESCRIPTION="A cross-platform Qt4 WebKit browser"
HOMEPAGE="http://arora.googlecode.com/"
SRC_URI="http://arora.googlecode.com/files/${P}.tar.gz"

LICENSE="|| ( GPL-3 GPL-2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="x11-libs/qt-webkit:4"
DEPEND="$RDEPEND"

ARORA_LANGS="es es_CR et_EE fr_CA gl ms nb_NO uk zh_CN"
ARORA_NOLONGLANGS="cs_CZ da_DK de_DE fr_FR he_IL hu_HU it_IT ja_JP nl_NL pl_PL
	ru_RU sk_SK tr_TR"

for L in $ARORA_LANGS; do
	IUSE="$IUSE linguas_$L"
done
for L in $ARORA_NOLONGLANGS; do
	IUSE="$IUSE linguas_${L%_*}"
done

src_prepare() {
	# process linguas
	local langs=
	for lingua in $LINGUAS; do
		if has $lingua $ARORA_LANGS; then
			langs="$langs ${lingua}.ts"
		else
			for a in $ARORA_NOLONGLANGS; do
				if [[ $lingua == ${a%_*} ]]; then
					langs="$langs ${a}.ts"
				fi
			done
		fi
	done

	# remove all translations, then add only the ones we want
	sed -i '/ts/d' src/locale/locale.pri || die 'sed failed'
	sed -i "/^TRANSLATIONS/s:\\\:${langs}:" src/locale/locale.pri \
		|| die 'sed failed'
}

src_configure() {
	eqmake4 arora.pro PREFIX="${D}/usr"
}

src_compile() {
	emake || die "make failed"

	# don't pre-strip
	sed -i "/strip/d" src/Makefile || die 'sed failed'
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die 'make install failed'
	dodoc AUTHORS ChangeLog README
}